zircon/system/ulib/storage/buffer/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/zircon/zx_library.gni")

zx_library("buffer") {
  sdk = "source"
  sdk_headers = [
    "storage/buffer/array_buffer.h",
    "storage/buffer/block_buffer_view.h",
    "storage/buffer/block_buffer.h",
    "storage/buffer/blocking_ring_buffer.h",
    "storage/buffer/owned_vmoid.h",
    "storage/buffer/resizeable_vmo_buffer.h",
    "storage/buffer/ring_buffer.h",
    "storage/buffer/vmo_buffer.h",
    "storage/buffer/vmoid_registry.h",
  ]
  sources = [
    "array_buffer.cc",
    "block_buffer.cc",
  ]
  deps = [ "//zircon/third_party/ulib/safemath" ]
  public_deps = [ "//sdk/fidl/fuchsia.hardware.block.driver:fuchsia.hardware.block.driver_banjo_cpp" ]

  if (is_fuchsia) {
    sources += [
      "blocking_ring_buffer.cc",
      "owned_vmoid.cc",
      "resizeable_vmo_buffer.cc",
      "ring_buffer.cc",
      "vmo_buffer.cc",
    ]
    public_deps += [
      "//zircon/system/ulib/fbl",
      "//zircon/system/ulib/fzl",
      "//zircon/system/ulib/storage/operation",
      "//zircon/system/ulib/zx",
    ]
    deps += [
      "//sdk/lib/fdio",
      "//zircon/system/ulib/fbl",

      # TODO(https://fxbug.dev/42113969): Clean up any remaining 'fs' dependencies. Only for fs/trace
      "//src/storage/lib/vfs/cpp",
      "//zircon/system/ulib/fzl",
      "//zircon/system/ulib/storage/operation",
      "//zircon/system/ulib/zx",
    ]
  }
}

group("tests") {
  testonly = true
  deps = [ "test:tests" ]
}