zircon/kernel/lib/arch/riscv64/BUILD.gn

# Copyright 2023 The Fuchsia Authors
#
# Use of this source code is governed by a MIT-style
# license that can be found in the LICENSE file or at
# https://opensource.org/licenses/MIT

import("//build/cpp/library_headers.gni")
import("//zircon/system/ulib/hwreg/hwreg_asm_header.gni")

library_headers("headers") {
  visibility = [ "../*" ]

  headers = []

  public_deps = [
    # <lib/arch/internal/zbi-constants.h> has #include <fidl/zbi/data/asm/zbi.h>
    "//sdk/fidl/zbi:zbi_zither.asm",

    # <lib/arch/zbi-boot.h> has #include <lib/zbi-format/zbi.h>.
    # <lib/arch/internal/zbi-constants.h> has #include <lib/zbi-format/zbi.h>.
    "//sdk/lib/zbi-format",
  ]
}

static_library("riscv64") {
  visibility = [ "../*" ]

  public_deps = [ ":headers" ]

  include_dirs = [
    "include",
    "../include",
  ]

  sources = [ "shadow-call-stack.S" ]

  if (is_kernel) {
    sources += [ "random.cc" ]
    deps = [
      "//zircon/kernel/lib/ktl",
      "//zircon/kernel/lib/libc",
    ]
  }
}