src/ui/scenic/lib/image-compression/BUILD.gn

# Copyright 2022 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")

group("image-compression") {
  testonly = true
  deps = [
    ":package",
    "tests",
  ]
}

source_set("lib") {
  sources = [
    "image_compression.cc",
    "image_compression.h",
  ]

  public_deps = [
    "//sdk/fidl/fuchsia.ui.compression.internal:fuchsia.ui.compression.internal_cpp",
    "//sdk/fidl/fuchsia.ui.compression.internal:fuchsia.ui.compression.internal_cpp_hlcpp_conversion",
    "//sdk/fidl/fuchsia.ui.compression.internal:fuchsia.ui.compression.internal_hlcpp",
    "//sdk/lib/async",
    "//sdk/lib/async:async-cpp",
    "//sdk/lib/inspect/component/cpp",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/syslog/cpp",
  ]

  deps = [
    "//sdk/fidl/fuchsia.images:fuchsia.images_hlcpp",
    "//src/lib/fostr/fidl/fuchsia.images",
    "//src/lib/fsl",
    "//third_party/libpng",
  ]
}

executable("bin") {
  output_name = "image-compression"

  sources = [ "main.cc" ]

  deps = [
    ":lib",
    "//sdk/lib/async-default",
    "//sdk/lib/async-loop:async-loop-cpp",
    "//sdk/lib/async-loop:async-loop-default",
    "//sdk/lib/component/outgoing/cpp",
    "//sdk/lib/inspect/component/cpp",
    "//sdk/lib/sys/cpp",
  ]
}

fuchsia_component("component") {
  component_name = "image-compression"
  manifest = "meta/image_compression.cml"
  deps = [ ":bin" ]
}

fuchsia_package("package") {
  package_name = "image-compression"
  deps = [ ":component" ]
}