src/ui/input/drivers/i2c-hid/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/components.gni")
import("//build/drivers.gni")
import("//build/test.gni")

group("drivers") {
  deps = [ ":i2c-hid" ]
}

driver_bind_rules("i2c_hid_bind") {
  rules = "i2c_hid.bind"
  tests = "tests.json"
  deps = [
    "//sdk/fidl/fuchsia.hardware.interrupt:fuchsia.hardware.interrupt_bindlib",
    "//sdk/fidl/fuchsia.hardware.sysmem:fuchsia.hardware.sysmem_bindlib",
    "//src/devices/bind/fuchsia.acpi",
  ]
}

fuchsia_driver("i2c-hid-driver") {
  output_name = "i2c-hid"
  configs += [
    "//build/config:all_source",
    "//build/config/fuchsia:enable_zircon_asserts",
  ]
  sources = [ "i2c-hid.cc" ]
  deps = [
    "//sdk/banjo/fuchsia.hardware.hidbus:fuchsia.hardware.hidbus_banjo_cpp",
    "//sdk/fidl/fuchsia.hardware.acpi:fuchsia.hardware.acpi_cpp",
    "//src/devices/i2c/lib/device-protocol-i2c-channel",
    "//src/devices/lib/acpi",
    "//src/devices/lib/driver",
    "//src/devices/lib/fragment-irq:dfv1",
    "//src/lib/ddk",
    "//src/ui/input/lib/hid",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/sync",
    "//zircon/system/ulib/trace",
  ]
}

fuchsia_driver_component("i2c-hid") {
  component_name = "i2c-hid"
  deps = [
    ":i2c-hid-driver",
    ":i2c_hid_bind",
  ]
  info = "i2c-hid-info.json"
  manifest = "meta/i2c-hid.cml"
}

fuchsia_driver_package("package") {
  package_name = "i2c-hid"
  driver_components = [ ":i2c-hid" ]
}

test("i2c-hid-test") {
  configs += [ "//build/config:all_source" ]
  sources = [
    "i2c-hid-test.cc",
    "i2c-hid.cc",
  ]
  deps = [
    ":i2c_hid_bind",
    "//sdk/banjo/fuchsia.hardware.hidbus:fuchsia.hardware.hidbus_banjo_cpp",
    "//sdk/fidl/fuchsia.hardware.acpi:fuchsia.hardware.acpi_cpp",
    "//sdk/lib/async_patterns/cpp",
    "//sdk/lib/component/outgoing/cpp",
    "//src/devices/i2c/lib/device-protocol-i2c-channel",
    "//src/devices/i2c/testing/fake-i2c",
    "//src/devices/lib/acpi",
    "//src/devices/lib/acpi/mock:mock-acpi",
    "//src/devices/lib/fragment-irq:dfv1",
    "//src/devices/testing/mock-ddk",
    "//src/lib/ddk",
    "//src/ui/input/lib/hid",
    "//src/ui/input/testing/fake-hidbus-ifc",
    "//zircon/system/ulib/async:async-cpp",
    "//zircon/system/ulib/async-default",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/sync",
    "//zircon/system/ulib/trace",
    "//zircon/system/ulib/zxtest",
  ]
}

fuchsia_unittest_package("i2c-hid-test-package") {
  package_name = "i2c-hid-test"
  deps = [ ":i2c-hid-test" ]
  test_specs = {
    log_settings = {
      max_severity = "ERROR"
    }
  }
}

group("tests") {
  testonly = true
  deps = [
    ":i2c-hid-test-package",
    ":i2c_hid_bind_test",
  ]
}