src/sys/component_manager/tests/abi_compatibility/BUILD.gn

# Copyright 2022 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/component/config.gni")
import("//build/components.gni")
import("//build/rust/rustc_binary.gni")

rustc_test("integration_bin") {
  edition = "2024"
  name = "abi_integration_test"
  source_root = "src/integration_test.rs"
  deps = [
    "//sdk/fidl/fuchsia.component.decl:fuchsia.component.decl_rust",
    "//sdk/fidl/fuchsia.component.resolution:fuchsia.component.resolution_rust",
    "//sdk/fidl/fuchsia.mem:fuchsia.mem_rust",
    "//sdk/fidl/fuchsia.sys2:fuchsia.sys2_rust",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/lib/fuchsia-component-test",
    "//src/lib/versioning/version-history/rust",
    "//src/lib/versioning/version-history/rust/data",
    "//src/sys/lib/cm_rust",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:assert_matches",
    "//third_party/rust_crates:futures",
  ]
  sources = [ "src/integration_test.rs" ]
}

fuchsia_component("integration_test") {
  testonly = true
  manifest = "meta/integration_test.cml"
  deps = [ ":integration_bin" ]
}

fuchsia_test_package("abi_compatibility_tests") {
  test_components = [ ":integration_test" ]
  deps = [ ":abi_compat_component_manager" ]
}

component_config("component_manager_config") {
  sources = [
    "//src/sys/component_manager/configs/test_config.base.json5",
    "configs/abi_compat_cm_config.json5",
  ]
}

fuchsia_component("abi_compat_component_manager") {
  testonly = true
  deps = [
    ":component_manager_config",
    "//src/sys/component_manager:bin_with_tracing",
  ]
  manifest = "//src/sys/component_manager/meta/component_manager.cml"
}

group("tests") {
  testonly = true
  deps = [ ":abi_compatibility_tests" ]
}