src/lib/diagnostics/log/rust/tests/BUILD.gn

# Copyright 2026 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/components.gni")
import("//build/drivers.gni")
import("//build/rust/rustc_binary.gni")
import("//build/rust/rustc_test.gni")

rustc_binary("logger_rust_bin") {
  testonly = true
  name = "logger_rust"
  edition = "2024"
  source_root = "src/logger_rust.rs"
  sources = [ "src/logger_rust.rs" ]
  deps = [
    "//src/lib/fuchsia",
    "//third_party/rust_crates:log",
  ]
}

executable("logger_cpp_bin") {
  testonly = true
  output_name = "logger_cpp"
  sources = [ "logger_cpp.cc" ]
  deps = [ "//sdk/lib/syslog/cpp" ]
}

driver_bind_rules("logger_driver_bind") {
  testonly = true
  bind_output = "logger_driver.bindbc"
  rules = "meta/logger_driver.bind"
  deps = [ "//src/devices/bind/fuchsia.test" ]
}

fuchsia_cc_driver("logger_driver_bin") {
  testonly = true
  output_name = "logger"
  sources = [ "logger_driver.cc" ]
  deps = [
    ":logger_driver_bind",
    "//sdk/lib/driver/component/cpp",
    "//sdk/lib/driver/logging/cpp",
    "//src/devices/lib/driver:driver_runtime",
  ]
}

fuchsia_component("logger_rust") {
  testonly = true
  manifest = "meta/logger_rust.cml"
  deps = [ ":logger_rust_bin" ]
  check_includes = false  # see logger_rust.cml
}

fuchsia_component("logger_cpp") {
  testonly = true
  manifest = "meta/logger_cpp.cml"
  deps = [ ":logger_cpp_bin" ]
  check_includes = false  # see logger_cpp.cml
}

fuchsia_driver_component("logger_driver") {
  testonly = true
  deps = [ ":logger_driver_bin" ]
  info = "meta/logger-info.json"
  manifest = "meta/logger_driver.cml"
}

rustc_test("log_integration_test_bin") {
  name = "log_integration_test"
  edition = "2024"
  source_root = "src/lib.rs"
  sources = [ "src/lib.rs" ]
  deps = [
    "//sdk/fidl/fuchsia.diagnostics:fuchsia.diagnostics_rust",
    "//src/lib/diagnostics/reader/rust",
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-component-test",
    "//src/sys/lib/cm_rust/testing",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:test-case",
  ]
}

rustc_test("log_driver_integration_test_bin") {
  name = "log_driver_integration_test"
  edition = "2024"
  source_root = "src/lib_driver.rs"
  sources = [ "src/lib_driver.rs" ]
  deps = [
    "//sdk/fidl/fuchsia.diagnostics:fuchsia.diagnostics_rust",
    "//sdk/fidl/fuchsia.driver.test:fuchsia.driver.test_rust",
    "//sdk/lib/driver_test_realm/realm_builder/rust",
    "//src/lib/diagnostics/reader/rust",
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-component",
    "//src/lib/fuchsia-component-test",
    "//third_party/rust_crates:futures",
  ]
}

fuchsia_test_component("log_integration") {
  component_name = "log_integration_test"
  manifest = "meta/test.cml"
  deps = [ ":log_integration_test_bin" ]
}

fuchsia_test_component("log_driver_integration") {
  component_name = "log_driver_integration_test"
  manifest = "meta/test_driver.cml"
  deps = [ ":log_driver_integration_test_bin" ]

  check_includes = false  # see test_driver.cml
}

fuchsia_test_package("log_integration_test") {
  test_components = [ ":log_integration" ]
  deps = [
    ":logger_cpp",
    ":logger_rust",
  ]
  subpackages = [ "//src/diagnostics/archivist:archivist-for-embedding" ]
}

fuchsia_test_package("log_driver_integration_test") {
  test_components = [ ":log_driver_integration" ]
  deps = [ ":logger_driver" ]
  subpackages = [ "//src/diagnostics/archivist:archivist-for-embedding" ]
}

group("tests") {
  testonly = true
  deps = [
    ":log_driver_integration_test",
    ":log_integration_test",
  ]
}