src/graphics/magma/tests/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/testing/environments.gni")
import("//src/graphics/lib/magma/gnbuild/magma.gni")

group("tests") {
  testonly = true
  public_deps = [
    ":magma_nonhardware_tests",
    "codegen",
    "icd_strip",
    "integration:tests",
    "//src/graphics/lib/magma/src/libmagma:verify_magma",
    "//src/graphics/lib/magma/src/tools:tests",
    "//src/graphics/magma/lib/magma_service/sys_driver/tests",
  ]

  # Add driver dependencies:
  public_deps += [
    "//src/graphics/bin/vulkan_loader",
    "//src/graphics/drivers/msd-arm-mali/tests",
    "//src/graphics/drivers/msd-intel-gen/tests",
    "//src/graphics/drivers/msd-virtio-gpu/tests",
    "//src/graphics/drivers/msd-vsi-vip/tests/integration",
    "//src/graphics/drivers/msd-vsi-vip/tests/unit_tests:msd-vsi-vip-nonhardware-tests",
  ]
  if (target_cpu == "x64") {
    public_deps += [
      "//src/graphics/drivers/intel-gen/icd:mesa_integration_tests",
      "//src/graphics/drivers/intel-gen/icd:mesa_unit_tests",
    ]
  }

  # Ensure the test MSDs are built even when not deployed
  public_deps += [
    "//src/graphics/drivers/msd-arm-mali:msd_arm_test",
    "//src/graphics/drivers/msd-intel-gen:msd_intel_test",
    "//src/graphics/drivers/msd-vsi-vip:msd_vsi_test",
  ]
}

# Tests that require a working libvulkan to run.
group("vulkan-tests") {
  testonly = true
  public_deps = [ "//src/graphics/tests:vulkan-tests" ]
}

# Packages needed for L0 from //doc/the-book/magma/contributing.md
group("l0") {
  testonly = true
  deps = [
    ":tests",
    ":vulkan-tests",
  ]
}

# Packages needed for L1
group("l1") {
  testonly = true
  deps = [
    ":l0",
    "//src/graphics/examples:vkcube-on-fb",
    "//src/graphics/examples:vkcube-on-scenic",
    "//src/graphics/lib/magma/src/tools",
    "//src/lib/vulkan/tests:image-pipe-swapchain-tests",
    "//src/ui:ui_package",
  ]
}

fuchsia_unittest_package("magma_nonhardware_tests") {
  manifest = "meta/magma_nonhardware_tests.cml"
  deps = [ "unit_tests" ]
  test_specs = {
    log_settings = {
      max_severity = "ERROR"
    }
  }
  test_type = "system"
}