src/graphics/display/lib/coordinator-getter/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.
import("//build/components.gni")
import("//build/test.gni")

# Provides a C++ utility function GetCoordinator() which connects to and
# interacts with the fuchsia.hardware.display.Service service, found within
# the component's environment.
source_set("client") {
  sources = [
    "client.cc",
    "client.h",
  ]
  public_deps = [
    "//sdk/fidl/fuchsia.hardware.display:fuchsia.hardware.display_cpp",
    "//sdk/lib/fit-promise",
  ]
  deps = [
    "//sdk/fidl/fuchsia.io:fuchsia.io_cpp",
    "//sdk/lib/async-default",
    "//sdk/lib/component/incoming/cpp",
    "//sdk/lib/fdio",
    "//sdk/lib/syslog/cpp",
    "//src/lib/files",
    "//zircon/system/ulib/trace",
    "//zircon/system/ulib/zx",
  ]
}

# Test the client getting display Coordinator with access to display.Provider
# service.
test("get_hardware_display_coordinator_test_bin") {
  sources = [ "tests/get_hardware_display_coordinator_test.cc" ]

  deps = [
    ":client",
    "//sdk/lib/component/incoming/cpp",
    "//sdk/lib/fit-promise",
    "//src/lib/fxl/test:gtest_main",
    "//src/lib/testing/loop_fixture",
    "//src/lib/testing/predicates",
    "//third_party/googletest:gtest",
  ]
}

fuchsia_unittest_package("get_hardware_display_coordinator_test") {
  deps = [
    ":get_hardware_display_coordinator_test_bin",
    "//src/graphics/display/testing/fake-display-stack-host:child-component-with-default-config",
  ]
  manifest = "tests/meta/get_hardware_display_coordinator_test.cml"
  test_specs = {
    log_settings = {
      max_severity = "ERROR"
    }
  }
  test_type = "vulkan"
}

group("tests") {
  testonly = true
  deps = [ ":get_hardware_display_coordinator_test" ]
}