src/devices/power/drivers/aml-meson-power/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/components.gni")
import("//build/drivers.gni")
import("//build/test.gni")

driver_bind_rules("aml-meson-power-bind") {
  rules = "aml-power.bind"
  bind_output = "aml-meson-power.bindbc"
  tests = "bind-tests.json"
  deps = [
    "//sdk/fidl/fuchsia.hardware.pwm:fuchsia.hardware.pwm_bindlib",
    "//sdk/fidl/fuchsia.hardware.vreg:fuchsia.hardware.vreg_bindlib",
    "//src/devices/bind/fuchsia.amlogic.platform",
    "//src/devices/bind/fuchsia.amlogic.platform.a311d",
    "//src/devices/bind/fuchsia.google.platform",
    "//src/devices/bind/fuchsia.regulator",
  ]
}

fuchsia_driver("aml-meson-power-driver") {
  output_name = "aml-meson-power"
  defines = [ "_ALL_SOURCE" ]
  configs += [ "//build/config/fuchsia:enable_zircon_asserts" ]
  sources = [
    "aml-power.cc",
    "aml-power.h",
  ]
  public_deps = [ "//sdk/fidl/fuchsia.hardware.pwm:fuchsia.hardware.pwm_cpp" ]
  deps = [
    ":aml-meson-power-bind",
    "//sdk/banjo/fuchsia.hardware.powerimpl:fuchsia.hardware.powerimpl_banjo_cpp",
    "//sdk/fidl/fuchsia.hardware.vreg:fuchsia.hardware.vreg_cpp",
    "//sdk/lib/fidl",
    "//src/devices/bus/lib/device-protocol-pdev",
    "//src/devices/lib/amlogic",
    "//src/devices/lib/driver",
    "//src/lib/ddk",
    "//src/lib/ddktl",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/hwreg",
    "//zircon/system/ulib/sync",
    "//zircon/system/ulib/zx",
  ]
}

fuchsia_driver_component("aml-meson-power") {
  info = "aml-meson-power-info.json"
  component_name = "aml-meson-power"
  deps = [ ":aml-meson-power-driver" ]
  manifest = "meta/aml-meson-power.cml"
}

fuchsia_driver_package("package") {
  package_name = "aml-meson-power"
  driver_components = [ ":aml-meson-power" ]
}

test("aml-meson-power-test-bin") {
  output_name = "aml-meson-power-test"
  sources = [
    "aml-power-test.cc",
    "aml-power.cc",
    "aml-power.h",
  ]
  deps = [
    ":aml-meson-power-bind",
    "//sdk/banjo/fuchsia.hardware.powerimpl:fuchsia.hardware.powerimpl_banjo_cpp",
    "//sdk/banjo/fuchsia.hardware.thermal:fuchsia.hardware.thermal_banjo_cpp",
    "//sdk/fidl/fuchsia.hardware.pwm:fuchsia.hardware.pwm_cpp_testing",
    "//sdk/fidl/fuchsia.hardware.vreg:fuchsia.hardware.vreg_cpp_testing",
    "//sdk/lib/async_patterns/testing/cpp",
    "//src/devices/bind/fuchsia.amlogic.platform:fuchsia.amlogic.platform_cpp",
    "//src/devices/bus/lib/device-protocol-pdev",
    "//src/devices/lib/amlogic",
    "//src/devices/lib/mmio",
    "//src/devices/testing/no_ddk",
    "//src/lib/ddk",
    "//src/lib/ddktl",
    "//zircon/system/ulib/async-default",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/hwreg",
    "//zircon/system/ulib/mock-function",
    "//zircon/system/ulib/sync",
    "//zircon/system/ulib/zx",
    "//zircon/system/ulib/zxtest",
  ]
}

fuchsia_unittest_package("aml-meson-power-test") {
  deps = [ ":aml-meson-power-test-bin" ]
  test_specs = {
    environments = basic_envs
  }
}

group("tests") {
  testonly = true
  deps = [
    ":aml-meson-power-bind_test",
    ":aml-meson-power-test",
  ]
}