src/devices/board/drivers/qemu-arm64/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/drivers.gni")
import("//src/devices/bus/drivers/pci/pci.gni")

driver_bind_rules("qemu-arm64_bind") {
  rules = "qemu-arm64.bind"
  tests = "bind_tests.json"
  deps = [
    "//sdk/fidl/fuchsia.hardware.platform.bus:fuchsia.hardware.platform.bus_bindlib",
    "//src/devices/bind/fuchsia.platform",
  ]
}

group("tests") {
  testonly = true
  deps = [ ":qemu-arm64_bind_test" ]
}

fuchsia_driver("qemu-arm64-driver") {
  output_name = "qemu-arm64"
  configs += [
    "//build/config:all_source",
    "//build/config/fuchsia:enable_zircon_asserts",
  ]
  sources = [
    "qemu-bus.cc",
    "qemu-kpci.cc",
    "qemu-rtc.cc",
    "qemu-sysmem.cc",
  ]
  deps = [
    ":qemu-arm64_bind",
    "//sdk/fidl/fuchsia.hardware.platform.bus:fuchsia.hardware.platform.bus_cpp",
    "//sdk/fidl/fuchsia.hardware.sysmem:fuchsia.hardware.sysmem_cpp",
    "//sdk/lib/driver/component/cpp",
    "//src/devices/bind/fuchsia:fuchsia_cpp",
    "//src/devices/bind/fuchsia.platform:fuchsia.platform_cpp",
    "//src/devices/lib/driver",
    "//src/devices/lib/driver:driver_runtime",
    "//src/devices/pci/lib/pci",
    "//src/lib/ddk",
    "//src/lib/ddktl",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/zx",
  ]

  if (platform_enable_user_pci) {
    defines = [ "ENABLE_USER_PCI" ]
    sources -= [ "qemu-kpci.cc" ]
    sources += [ "qemu-pci.cc" ]
  }

  if (current_cpu == "arm64") {
    # TODO(https://fxbug.dev/42124149): restore some form of data dependency on qemu
    # boot shims.
  }
}

fuchsia_driver_component("qemu-arm64") {
  component_name = "qemu-arm64"
  deps = [ ":qemu-arm64-driver" ]
  info = "qemu-arm64-info.json"
  manifest = "meta/qemu-arm64.cml"
}

fuchsia_driver_package("package") {
  package_name = "qemu-arm64"
  driver_components = [ ":qemu-arm64" ]
}