src/devices/bin/devfs/BUILD.gn

# Copyright 2022 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")

group("devfs") {
  deps = [ ":package" ]
}

executable("bin") {
  output_name = "devfs"

  sources = [ "main.cc" ]

  deps = [
    "//sdk/fidl/fuchsia.process.lifecycle:fuchsia.process.lifecycle_cpp",
    "//sdk/lib/component/incoming/cpp",
    "//sdk/lib/component/outgoing/cpp",
    "//sdk/lib/syslog/cpp",
    "//src/lib/fxl",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
  ]
}

fuchsia_component("component") {
  component_name = "devfs"
  manifest = "meta/devfs.cml"
  deps = [ ":bin" ]
}

# Used for /bootstrap/devfs-with-pkg since that component should not be marked
# `main_process_critical`
fuchsia_component("component-non-critical") {
  component_name = "devfs-pkg"
  manifest = "meta/devfs-base.shard.cml"
  deps = [ ":bin" ]
}

fuchsia_component("component-for-test") {
  component_name = "devfs"
  manifest = "meta/devfs-base.shard.cml"
  deps = [ ":bin" ]
}

fuchsia_package("package") {
  package_name = "devfs"
  deps = [
    ":component",
    ":component-non-critical",
  ]
}