src/connectivity/network/testing/netemul/configurable-netstack/tests/BUILD.gn

# Copyright 2022 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_binary.gni")
import("//build/rust/rustc_library.gni")
import("//build/rust/rustc_test.gni")

rustc_library("lib") {
  edition = "2021"
  name = "configurable_netstack_test"
  testonly = true
  deps = [ "//src/connectivity/lib/net-declare" ]
  source_root = "src/lib.rs"
  sources = [ "src/lib.rs" ]
  configs -= [ "//build/config/rust/lints:allow_unused_results" ]
  disable_rustdoc = true
}

rustc_test("client") {
  edition = "2021"
  name = "configurable_netstack_test_client"
  deps = [
    ":lib",
    "//sdk/fidl/fuchsia.net:fuchsia.net_rust",
    "//sdk/fidl/fuchsia.net.interfaces:fuchsia.net.interfaces_rust",
    "//sdk/fidl/fuchsia.net.interfaces.admin:fuchsia.net.interfaces.admin_rust",
    "//sdk/fidl/fuchsia.net.root:fuchsia.net.root_rust",
    "//sdk/fidl/fuchsia.net.routes:fuchsia.net.routes_rust",
    "//src/connectivity/lib/net-declare",
    "//src/connectivity/lib/net-types",
    "//src/connectivity/network/testing/netemul/sync-manager/rust:lib",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/lib/network/fidl_fuchsia_net_interfaces_ext",
    "//src/lib/network/fidl_fuchsia_net_routes_ext",
    "//third_party/rust_crates:futures-util",
    "//third_party/rust_crates:test-case",
  ]
  source_root = "src/client.rs"
  sources = [ "src/client.rs" ]
  configs -= [ "//build/config/rust/lints:allow_unused_results" ]
}

rustc_binary("server") {
  edition = "2021"
  testonly = true
  deps = [
    ":lib",
    "//src/connectivity/network/testing/netemul/sync-manager/rust:lib",
    "//src/lib/diagnostics/log/rust",
    "//src/lib/fuchsia-async",
    "//third_party/rust_crates:tracing",
  ]
  source_root = "src/server.rs"
  sources = [ "src/server.rs" ]
  configs -= [ "//build/config/rust/lints:allow_unused_results" ]
}

fuchsia_test_component("client-component") {
  component_name = "client"
  manifest = "meta/client.cml"
  deps = [ ":client" ]
}

fuchsia_test_component("server-component") {
  component_name = "server"
  manifest = "meta/server.cml"
  deps = [ ":server" ]
}

fuchsia_test_component("configurable-netstack-test") {
  manifest = "meta/configurable-netstack-test.cml"
  deps = [
    ":client-component",
    ":server-component",
    "//src/connectivity/network/testing/netemul/configurable-netstack",
    "//src/connectivity/network/testing/netemul/sync-manager",
  ]
}

fuchsia_test_package("configurable-netstack-tests") {
  test_components = [ ":configurable-netstack-test" ]
}

group("tests") {
  testonly = true
  deps = [ ":configurable-netstack-tests" ]
}