src/bringup/bin/device-name-provider/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/zbi/kernel_cmdline.gni")

group("tests") {
  testonly = true
  deps = [ "tests" ]
}

source_set("args") {
  sources = [ "args.cc" ]
  deps = [
    "//sdk/fidl/fuchsia.boot:fuchsia.boot_cpp",
    "//sdk/lib/component/incoming/cpp",
    "//zircon/system/ulib/zx",
  ]
}

executable("device-name-provider") {
  sources = [ "device-name-provider.cc" ]
  deps = [
    ":args",
    "//sdk/fidl/fuchsia.device:fuchsia.device_cpp",
    "//sdk/lib/component/outgoing/cpp",
    "//sdk/lib/fdio",
    "//src/bringup/bin/netsvc:netifc-discover",
    "//zircon/system/ulib/async-default",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
  ]
}

fuchsia_component("component") {
  component_name = "device-name-provider"
  manifest = "meta/device-name-provider.cml"
  deps = [ ":device-name-provider" ]
}

fuchsia_package("package") {
  package_name = "device-name-provider"
  deps = [ ":component" ]
}

# command line package to be included for new-style nodename generation.
kernel_cmdline("nodenames-newgen") {
  args = [ "zircon.namegen=1" ]
}

# command line package to be included for old-style nodename generation.
kernel_cmdline("nodenames-oldgen") {
  args = [ "zircon.namegen=0" ]
}