sdk/ctf/tests/fidl/fuchsia.element/BUILD.gn

# Copyright 2021 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/testing/cc_test_executable.gni")
import("//sdk/ctf/build/ctf.gni")

group("tests") {
  testonly = true
  deps = [
    ":ctf-tests",
    ":fuchsia-element-tests-latest",
  ]
}

group("ctf-tests") {
  testonly = true
  deps = [ ":fuchsia-element-tests_archive" ]
}

cc_test_executable("element-manager-test-bin") {
  output_name = "element-manager-test"
  testonly = true
  sources = [ "element_manager_test.cc" ]
  deps = [
    "testing/fidl:fuchsia.element.test_hlcpp",
    "//sdk/fidl/fuchsia.component:fuchsia.component_hlcpp",
    "//sdk/fidl/fuchsia.component.sandbox:fuchsia.component.sandbox_hlcpp",
    "//sdk/fidl/fuchsia.element:fuchsia.element_hlcpp",
    "//sdk/lib/async-loop:async-loop-cpp",
    "//sdk/lib/async-loop:async-loop-default",
    "//sdk/lib/sys/cpp",
    "//sdk/testing/fidl:fidl_test_hlcpp",
    "//zircon/system/ulib/zxtest",
  ]
}

fuchsia_component("default") {
  manifest = "meta/default.cml"
  testonly = true
  deps = [ ":element-manager-test-bin" ]
}

ctf_fuchsia_package("fuchsia-element-tests") {
  package_name = "fuchsia-element-tests"
  testonly = true
  deps = [ ":default" ]
}

fuchsia_component("test-root") {
  manifest = "meta/test-root.cml"
}

fuchsia_test_package("fuchsia-element-tests-latest") {
  test_components = [ ":test-root" ]
  subpackages = [
    "testing/realm-factory",
    ":fuchsia-element-tests",
  ]
}