products/workbench/workbench_session/BUILD.gn

# Copyright 2023 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bazel/bazel_inputs.gni")
import("//build/components.gni")
import("//build/components/fuchsia_package_archive.gni")

fuchsia_component_manifest("workbench_session_component_manifest") {
  manifest = "meta/workbench_session.cml"
  component_name = "workbench_session"
}

fuchsia_component("workbench_session_component") {
  cm_label = ":workbench_session_component_manifest"
}

fuchsia_package("workbench_session") {
  package_name = "workbench_session"
  subpackages = [
    "//src/session/bin/element_manager",
    "//src/ui/bin/tiling_wm",
  ]
  deps = [ ":workbench_session_component" ]
}

# Make `workbench_session` available to products assembled with Bazel.
#
# TODO: b/295034058 - Make this less verbose.
fuchsia_package_archive("workbench_session_archive") {
  package = ":workbench_session"
}

bazel_input_resource("workbench_session_bazel_inputs") {
  deps = [ ":workbench_session_archive" ]
  sources = get_target_outputs(":workbench_session_archive")
  outputs = [ "{{source_file_part}}" ]
  gn_targets_name = "workbench_session_archive"
}