zircon/kernel/lib/fbl/BUILD.gn

# Copyright 2019 The Fuchsia Authors
#
# Use of this source code is governed by a MIT-style
# license that can be found in the LICENSE file or at
# https://opensource.org/licenses/MIT

import("//build/cpp/library_headers.gni")

static_library("fbl") {
  public_deps = [ ":headers" ]

  sources = [ "arena.cc" ]
  deps = [
    "//sdk/lib/fit",
    "//zircon/kernel/lib/ktl",
    "//zircon/kernel/lib/page",
    "//zircon/kernel/vm:headers",
    "//zircon/system/ulib/fbl",
  ]
}

library_headers("headers") {
  headers = []

  public_deps = [
    "//zircon/system/ulib/fbl:headers",

    # <fbl/gparena.h> has #include <lib/fit/defer.h>
    "//sdk/lib/fit:headers",

    # <fbl/arena.h> has #include <ktl/forward.h>.
    "//zircon/kernel/lib/ktl:headers",

    # <fbl/gparena.h> has #include <lib/page/size.h>
    # <fbl/paged_view.h> has #include <lib/page/size.h>
    "//zircon/kernel/lib/page:headers",
  ]
}

group("tests") {
  testonly = true
}

source_set("kernel-tests") {
  #TODO: testonly = true
  visibility = [
    ":*",
    "//zircon/kernel/lib:kernel-tests",
  ]
  sources = [
    "arena_tests.cc",
    "gparena_tests.cc",
    "name_tests.cc",
    "paged_view_tests.cc",
  ]

  deps = [
    ":headers",
    "//zircon/kernel/lib/page",
    "//zircon/kernel/lib/unittest",
  ]
}

group("phys-tests") {
  testonly = true
}

group("boot_tests") {
  testonly = true
}