src/virtualization/bin/vmm/device/virtio_balloon/BUILD.gn

# Copyright 2022 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_binary.gni")

group("tests") {
  testonly = true
  deps = [ ":virtio_balloon_unittests" ]
}

rustc_binary("virtio_balloon_bin") {
  name = "virtio_balloon_bin"
  edition = "2024"
  with_unit_tests = true

  sources = [
    "src/balloon_device.rs",
    "src/main.rs",
    "src/wire.rs",
  ]

  deps = [
    "//sdk/fidl/fuchsia.virtualization:fuchsia.virtualization_rust",
    "//sdk/fidl/fuchsia.virtualization.hardware:fuchsia.virtualization.hardware_rust",
    "//sdk/rust/zx",
    "//src/lib/diagnostics/inspect/runtime/rust",
    "//src/lib/diagnostics/inspect/rust",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-component",
    "//src/virtualization/lib/machina-virtio-device",
    "//src/virtualization/lib/virtio-device",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:bitflags",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:log",
    "//third_party/rust_crates:zerocopy",
  ]

  test_deps = [ "//src/lib/diagnostics/testing/diagnostics-assertions/rust:diagnostics-assertions" ]
}

fuchsia_unittest_package("virtio_balloon_unittests") {
  deps = [ ":virtio_balloon_bin_test" ]
}

fuchsia_component("virtio_balloon_component") {
  manifest = "meta/virtio_balloon.cml"
  deps = [ ":virtio_balloon_bin" ]
  component_name = "virtio_balloon"
}