src/sys/lib/elf_runner/tests/environ/BUILD.gn

# Copyright 2021 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_binary.gni")
import("//build/rust/rustc_test.gni")

group("environ") {
  testonly = true
  deps = [ ":elf_runner_environ_test" ]
}

rustc_binary("context-bin") {
  testonly = true
  edition = "2024"
  output_name = "context"
  deps = [
    "fidl:fuchsia.elf.test_rust",
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//third_party/rust_crates:futures",
  ]

  sources = [ "src/context.rs" ]
  source_root = "src/context.rs"
}

fuchsia_component("context-component") {
  testonly = true
  manifest = "meta/context.cml"
  component_name = "context"
  deps = [ ":context-bin" ]
}

rustc_test("test") {
  edition = "2024"
  name = "environ"

  deps = [
    "fidl:fuchsia.elf.test_rust",
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-component",
  ]

  sources = [ "src/lib.rs" ]
}

fuchsia_component("environ_integration_test") {
  testonly = true
  manifest = "meta/environ.cml"
  deps = [ ":test" ]
}

fuchsia_test_package("elf_runner_environ_test") {
  test_components = [ ":environ_integration_test" ]

  deps = [ ":context-component" ]
}