src/storage/lib/buffer/test/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/test.gni")

group("tests") {
  testonly = true
  deps = [ ":storage-buffer-tests" ]
}

test("storage_buffer") {
  if (is_fuchsia) {
    fdio_config = [ "//build/config/fuchsia:fdio_config" ]
    if (configs + fdio_config - fdio_config != configs) {
      configs -= fdio_config
    }
  }
  sources = [
    "array_buffer_test.cc",
    "block_buffer_view_test.cc",
    "blocking_ring_buffer_test.cc",
    "mapped_vmo_test.cc",
    "owned_vmoid_test.cc",
    "resizeable_vmo_buffer_test.cc",
    "ring_buffer_test.cc",
    "vmo_bitmap_storage_test.cc",
    "vmo_buffer_test.cc",
    "vmoid_registry_test.cc",
  ]
  deps = [
    "//sdk/lib/fdio",
    "//src/lib/fxl/test:gtest_main",
    "//src/lib/testing/predicates",
    "//src/storage/lib/buffer",
    "//third_party/googletest:gmock",
    "//third_party/googletest:gtest",
    "//zircon/system/ulib/bitmap",
  ]
}

fuchsia_component("storage-buffer-tests-component") {
  component_name = "storage-buffer-tests"
  testonly = true
  manifest = "meta/storage-buffer-tests.cml"
  deps = [ ":storage_buffer" ]
}

fuchsia_test_package("storage-buffer-tests") {
  test_specs = {
    log_settings = {
      max_severity = "ERROR"
    }
  }
  test_components = [ ":storage-buffer-tests-component" ]
}