src/starnix/tests/perf_event_open/BUILD.gn

# Copyright 2026 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_binary.gni")
import("//src/starnix/kernel/starnix.gni")
import("//src/starnix/tests/starnix_test_subpackages.gni")

rustc_binary("perf_event_open_integration_test_rustc") {
  testonly = true
  edition = "2024"
  source_root = "perf_event_open_integration_test.rs"
  sources = [ "perf_event_open_integration_test.rs" ]
  deps = [
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-component-test",
    "//src/sys/lib/component-events",
    "//third_party/rust_crates:assert_matches",
    "//third_party/rust_crates:log",
  ]
}

fuchsia_component("perf_event_open_integration_test_linux_component") {
  component_name = "perf_event_open_integration_test_linux"
  manifest = "meta/perf_event_open_integration_test_linux.cml"
}

resource("perf_event_open_test_binary_resource") {
  testonly = true
  _out_dir = get_label_info(
          "//src/starnix/tests/syscalls/cpp:starnix_perf_event_open_test_bin($target_linux_toolchain)",
          "root_out_dir")
  sources = [ "${_out_dir}/starnix_perf_event_open_test_bin" ]
  outputs = [ "data/tests/starnix_perf_event_open_test_bin" ]
  deps = [ "//src/starnix/tests/syscalls/cpp:starnix_perf_event_open_test_bin($target_linux_toolchain)" ]
}

fuchsia_test_component("perf_event_open_integration_test_component") {
  component_name = "perf_event_open_integration_test"
  manifest = "meta/perf_event_open_integration_test.cml"
  deps = [ ":perf_event_open_integration_test_rustc" ]
  test_type = "starnix"
}

fuchsia_test_package("perf_event_open_integration_test") {
  test_components = [ ":perf_event_open_integration_test_component" ]
  deps = [
    ":perf_event_open_integration_test_linux_component",
    ":perf_event_open_test_binary_resource",
  ]
  subpackages = [
    "//src/starnix/kernel:starnix_kernel_package",
    "//src/starnix/containers/debian:debian_package",
  ]
  test_specs = {
    parallel = 1
  }
}

group("tests") {
  testonly = true
  deps = [ ":perf_event_open_integration_test" ]
}