src/starnix/tests/diagnostics/syscall_logging/BUILD.gn

# Copyright 2026 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_binary.gni")
import("//src/starnix/build/args.gni")
import("//src/starnix/build/starnix_linux_executable.gni")
import("//src/starnix/kernel/starnix.gni")

group("syscall_logging") {
  testonly = true
  deps = [ ":tests" ]
}

group("tests") {
  testonly = true

  # The logs being tested here are not enabled in release builds by default.
  if (compilation_mode != "release" ||
      starnix_enable_trace_and_debug_logs_in_release) {
    deps = [ ":starnix_syscall_logging_test" ]
  }
}

starnix_linux_executable("workload_bin") {
  testonly = true
  sources = [ "src/workload.cc" ]
}

rustc_binary("test_driver_bin") {
  edition = "2024"
  sources = [ "src/main.rs" ]
  name = "syscall_logging_test_driver"
  deps = [
    "//sdk/fidl/fuchsia.component:fuchsia.component_rust",
    "//sdk/fidl/fuchsia.starnix.container:fuchsia.starnix.container_rust",
    "//sdk/rust/zx",
    "//src/lib/diagnostics/reader/rust",
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-component",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:log",
  ]
}

fuchsia_component("workload") {
  testonly = true
  manifest = "meta/workload.cml"
  deps = [ ":workload_bin" ]
}

fuchsia_test_component("integration_test") {
  manifest = "meta/integration_test.cml"
  deps = [ ":test_driver_bin" ]
  test_type = "starnix"
}

fuchsia_test_package("starnix_syscall_logging_test") {
  test_components = [ ":integration_test" ]
  subpackages = [
    "//src/starnix/containers/debian:debian_package",
    "//src/starnix/kernel:starnix_kernel_package",
    "//src/performance/trace_manager:package_hermetic",
  ]
  deps = [ ":workload" ]
  test_specs = {
    package_resolution_timeout_secs = 660
  }
}