src/starnix/modules/syscalls/BUILD.gn

# Copyright 2026 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_library.gni")

group("tests") {
  testonly = true
  deps = [ ":starnix-syscalls-tests" ]
}

rustc_library("syscalls") {
  name = "starnix-modules-syscalls"
  edition = "2024"
  version = "0.1.0"
  source_root = "lib.rs"
  with_unit_tests = true

  sources = [
    "lib.rs",
    "misc.rs",
    "reboot.rs",
  ]

  # TODO(https://fxbug.dev/42059075): Re-enable starnix in these environments.
  exclude_toolchain_tags = [
    "asan",
    "hwasan",
  ]

  configs += [ "//src/starnix/build:kernel_library_config" ]

  deps = [
    "//sdk/fidl/fuchsia.buildinfo:fuchsia.buildinfo_rust",
    "//sdk/fidl/fuchsia.hardware.power.statecontrol:fuchsia.hardware.power.statecontrol_rust",
    "//sdk/rust/zx",
    "//src/lib/fuchsia-component",
    "//src/starnix/kernel/core",
    "//src/starnix/lib/linux_uapi",
    "//src/starnix/lib/starnix_crypto",
    "//src/starnix/lib/starnix_logging",
    "//src/starnix/lib/starnix_sync",
    "//src/starnix/lib/starnix_syscalls",
    "//src/starnix/lib/starnix_types",
    "//src/starnix/lib/starnix_uapi",
    "//third_party/rust_crates:bstr",
    "//third_party/rust_crates:zerocopy",
  ]
}

fuchsia_unittest_package("starnix-syscalls-tests") {
  manifest = "meta/starnix_syscalls_tests.cml"
  deps = [ ":syscalls_test" ]
  test_type = "starnix"
}