src/starnix/modules/cgroupfs/BUILD.gn

# Copyright 2024 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_library.gni")

group("tests") {
  testonly = true
  deps = [ ":starnix-cgroupfs-tests" ]
}

rustc_library("cgroupfs") {
  name = "starnix-modules-cgroupfs"
  edition = "2021"
  version = "0.1.0"
  source_root = "lib.rs"
  with_unit_tests = true

  sources = [
    "directory.rs",
    "events.rs",
    "freeze.rs",
    "fs.rs",
    "kill.rs",
    "lib.rs",
    "procs.rs",
  ]

  # TODO(https://fxbug.dev/42059075): Re-enable starnix in these environments.
  exclude_toolchain_tags = [
    "asan",
    "hwasan",
  ]

  configs += [ "//src/starnix/config:starnix_clippy_lints" ]

  deps = [
    "//src/starnix/kernel/core",
    "//src/starnix/lib/starnix_sync",
    "//src/starnix/lib/starnix_types",
    "//src/starnix/lib/starnix_uapi",
  ]

  test_deps = [ "//src/lib/fuchsia" ]
}

fuchsia_unittest_package("starnix-cgroupfs-tests") {
  manifest = "meta/starnix_cgroupfs_tests.cml"
  deps = [ ":cgroupfs_test" ]
  test_specs = {
    log_settings = {
      # Tests exercise failure cases, so ERROR logs are expected.
      max_severity = "ERROR"
    }
  }
  test_type = "starnix"
}