src/starnix/modules/boot/tests/basic/BUILD.gn

# Copyright 2025 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_binary.gni")
import("//src/starnix/build/starnix_linux_executable.gni")
import("//src/starnix/kernel/starnix.gni")

group("tests") {
  testonly = true
  deps = [ ":starnix_boot_notifier_test" ]
}

rustc_binary("bin") {
  testonly = true
  edition = "2024"
  output_name = "boot_notifier_test"
  sources = [ "src/main.rs" ]
  deps = [
    "//sdk/fidl/fuchsia.sys2:fuchsia.sys2_rust",
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-component",
    "//src/lib/fuchsia-component-test",
    "//src/sys/lib/component-events",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:log",
  ]
}

fuchsia_test_component("integration_test") {
  manifest = "meta/integration_test.cml"
  deps = [ ":bin" ]
  test_type = "starnix"
}

fuchsia_component("container") {
  testonly = true
  manifest = "meta/container.cml"
}

starnix_linux_executable("linux_boot_reader") {
  output_name = "boot_reader"
  testonly = true
  sources = [ "src/boot_reader.cc" ]
}

fuchsia_component("boot_reader") {
  testonly = true
  manifest = "meta/boot_reader.cml"
  deps = [ ":linux_boot_reader" ]
}

fuchsia_test_package("starnix_boot_notifier_test") {
  test_components = [ ":integration_test" ]
  deps = [
    ":boot_reader",
    ":container",
  ]
  subpackages = [
    "//src/starnix/containers/debian:debian_package",
    "//src/starnix/kernel:starnix_kernel_package",
  ]
}