src/memory/tools/BUILD.gn

# Copyright 2022 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bazel/bazel_test_suite.gni")
import("//build/python/python_host_test.gni")
import("//build/python/python_mobly_test.gni")
import("//build/testing/environments.gni")

if (is_host) {
  python_host_test("mem_digest_test") {
    main_source = "mem_digest_test.py"

    #TODO(b/361301238): Either delete these scripts or add type annotation.
    enable_mypy = false
    sources = [
      "digest.py",
      "mem_digest.py",
      "snapshot.py",
    ]
    extra_args = [
      "--test_dir_path",
      rebase_path("testdata", root_build_dir),
    ]
  }

  python_host_test("treemap_test") {
    main_source = "treemap_test.py"
    sources = [ "treemap.py" ]
    data_package_name = "webtreemap_assets"
    data_sources = [
      "//scripts/third_party/webtreemap/webtreemap.css",
      "//scripts/third_party/webtreemap/webtreemap.js",
    ]
  }

  python_mobly_test("components_sql_test") {
    main_source = "components_sql_test.py"
    sources = [ "components_sql.py" ]
    libraries = [
      "//src/testing/end_to_end/honeydew",
      "//src/testing/end_to_end/mobly_base_tests/fuchsia_base_test",
    ]
    test_data_deps =
        [ "//src/developer/ffx/plugins/profile:ffx_profile_tool_test_data" ]

    environments = [
      # Only enable for AEMU-x64 as host-tests aren't supported on QEMU-arm64.
      aemu_env,
      vim3_env,
    ]
  }
}

bazel_test_suite("bazel_tests") {
  host_tests = [ "//src/memory/tools:host_tests" ]
}

group("tests") {
  testonly = true
  public_deps = [
    ":bazel_tests",
    ":mem_digest_test($host_toolchain)",
    ":treemap_test($host_toolchain)",
    "dupefinder:tests",
  ]
}