src/lib/fdomain/client/BUILD.gn

# Copyright 2024 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_library.gni")
import("//build/rust/rustc_macro.gni")
import("//build/rust/rustc_test.gni")

rustc_library("client") {
  name = "fdomain_client"
  edition = "2024"
  with_unit_tests = true

  deps = [
    "//sdk/fidl/fuchsia.fdomain:fuchsia.fdomain_rust",
    "//sdk/rust/zx-status",
    "//sdk/rust/zx-types",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fidl/rust/fidl_message",
    "//src/lib/fidl/rust_next/fidl_next",
    "//src/lib/fidl/rust_next/fidl_next_codec",
    "//src/lib/fidl/rust_next/fidl_next_protocol",
    "//src/lib/fuchsia-async",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:log",
    "//third_party/rust_crates:rand",
  ]

  test_deps = [
    "//src/lib/fdomain/container",
    "//src/lib/fuchsia",
  ]

  sources = [
    "src/channel.rs",
    "src/event.rs",
    "src/event_pair.rs",
    "src/fidl.rs",
    "src/fidl_next.rs",
    "src/fidl_next/codec.rs",
    "src/fidl_next/has_executor.rs",
    "src/fidl_next/wire_handle.rs",
    "src/fidl_next/wire_types.rs",
    "src/handle.rs",
    "src/lib.rs",
    "src/responder.rs",
    "src/socket.rs",
    "src/test.rs",
  ]
}

rustc_library("flex_fdomain") {
  name = "flex_client"
  edition = "2024"
  with_unit_tests = true

  deps = [
    ":client",
    "//src/lib/fuchsia-async",
  ]
  features = [ "fdomain" ]

  sources = [ "src/flex.rs" ]
  source_root = "src/flex.rs"
}

rustc_library("flex_fidl") {
  name = "flex_client"
  edition = "2024"
  with_unit_tests = true

  deps = [
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia-async",
  ]

  if (is_fuchsia) {
    deps += [ "//sdk/rust/zx" ]
  }

  sources = [ "src/flex.rs" ]

  source_root = "src/flex.rs"
}

fuchsia_unittest_package("fdomain-client-tests") {
  deps = [ ":client_test" ]
}

group("tests") {
  public_deps = [ ":fdomain-client-tests" ]
  testonly = true
}