src/graphics/display/drivers/framebuffer-bochs-display/BUILD.gn

# Copyright 2024 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/components.gni")
import("//build/drivers.gni")
import("//build/test.gni")

driver_bind_rules("framebuffer-bochs-display-bind") {
  rules = "meta/framebuffer-bochs-display.bind"
  tests = "meta/framebuffer-bochs-display-bind-tests.json"

  deps = [
    "//sdk/fidl/fuchsia.hardware.pci:fuchsia.hardware.pci_bindlib",
    "//src/devices/bind/fuchsia.acpi",
    "//src/devices/bind/fuchsia.pci",
  ]
}

fuchsia_cc_driver("driver") {
  output_name = "framebuffer-bochs-display"
  configs += [ "//build/config/fuchsia:enable_zircon_asserts" ]

  sources = [
    "bochs-vbe-registers.h",
    "framebuffer-bochs-display.cc",
  ]
  deps = [
    ":framebuffer-bochs-display-bind",
    "//sdk/fidl/fuchsia.hardware.pci:fuchsia.hardware.pci_cpp",
    "//sdk/lib/driver/component/cpp",
    "//sdk/lib/driver/logging/cpp",
    "//sdk/lib/driver/mmio/cpp",
    "//src/devices/pci/lib/device-protocol-pci",
    "//src/graphics/display/lib/api-types/cpp",
    "//src/graphics/display/lib/framebuffer-display",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/hwreg",
  ]
}

fuchsia_driver_component("framebuffer-bochs-display") {
  component_name = "framebuffer-bochs-display"
  deps = [ ":driver" ]
  info = "meta/framebuffer-bochs-display-info.json"
  manifest = "meta/framebuffer-bochs-display.cml"
}

fuchsia_driver_package("package") {
  package_name = "framebuffer-bochs-display"
  driver_components = [ ":framebuffer-bochs-display" ]
}

group("tests") {
  testonly = true
  deps = [ ":framebuffer-bochs-display-bind_test" ]
}