src/devices/misc/drivers/test/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/drivers.gni")

driver_bind_rules("test_bind") {
  rules = "meta/test.bind"
  tests = "meta/bind_tests.json"
  deps = [
    "//src/devices/bind/fuchsia.test",
    "//src/devices/bind/fuchsia.test.platform",
  ]
}

group("tests") {
  testonly = true
  deps = [ ":test_bind_test" ]
}

fuchsia_cc_driver("test-driver") {
  output_name = "test"
  configs += [
    "//build/config:all_source",
    "//build/config/fuchsia:enable_zircon_asserts",
  ]
  sources = [
    "test.cc",
    "test.h",
  ]
  deps = [
    ":test_bind",
    "//sdk/lib/driver/component/cpp",
    "//src/devices/lib/driver:driver_runtime",
  ]
}

fuchsia_driver_component("test") {
  visibility = [
    ":*",
    "//sdk/lib/driver_test_realm/tests:*",
    "//src/connectivity/bluetooth/testing/bt-test-harness:*",
    "//src/connectivity/bluetooth/tests/bt-manifest-integration-tests:*",
    "//src/devices/block/drivers/ftl/tests:ftl-integration",
    "//src/devices/misc:drivers",
    "//src/devices/misc/drivers/test:*",
    "//src/devices/tests/bind-fail-test:*",
    "//src/devices/tests/ddk-metadata-test:*",
  ]
  component_name = "test"
  deps = [ ":test-driver" ]
  info = "meta/test-info.json"
  manifest = "meta/test.cml"
}