src/devices/bin/driver_tools/common/BUILD.gn

# Copyright 2022 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_library.gni")

template("fuchsia_driver_dev_lib") {
  rustc_library(target_name) {
    forward_variables_from(invoker,
                           "*",
                           [
                             "deps",
                             "features",
                           ])
    edition = "2024"
    with_unit_tests = true
    deps = [
      "//third_party/rust_crates:anyhow",
      "//third_party/rust_crates:futures",
    ]
    if (defined(invoker.deps)) {
      deps += invoker.deps
    }
    if (defined(invoker.features)) {
      features = invoker.features
    }
    sources = [ "src/lib.rs" ]
  }
}

fuchsia_driver_dev_lib("lib") {
  name = "fuchsia_driver_dev"
  deps = [
    "//sdk/fidl/fuchsia.driver.development:fuchsia.driver.development_rust_flex",
    "//sdk/fidl/fuchsia.driver.framework:fuchsia.driver.framework_rust_flex",
    "//src/lib/fdomain/client:flex_fidl",
  ]
}

fuchsia_driver_dev_lib("lib_fdomain") {
  name = "fuchsia_driver_dev_fdomain"
  deps = [
    "//sdk/fidl/fuchsia.driver.development:fuchsia.driver.development_rust_fdomain_flex",
    "//sdk/fidl/fuchsia.driver.framework:fuchsia.driver.framework_rust_fdomain_flex",
    "//src/lib/fdomain/client:flex_fdomain",
  ]
  features = [ "fdomain" ]
}