src/developer/ffx/tools/monitor/BUILD.gn

# Copyright 2025 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/host.gni")
import("//build/rust/rustc_library.gni")
import("//src/developer/ffx/build/ffx_tool.gni")

rustc_library("lib") {
  name = "ffx_tool_monitor"
  edition = "2024"
  with_unit_tests = true

  deps = [
    "//src/developer/ffx/config:lib",
    "//src/developer/ffx/lib/fho:lib",
    "//src/developer/ffx/lib/target:lib",
    "//src/developer/ffx/lib/writer:lib",
    "//src/developer/ffx/plugins/target/list/target_formatter",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-hyper",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:argh",
    "//third_party/rust_crates:async-trait",
    "//third_party/rust_crates:hyper",
    "//third_party/rust_crates:log",
    "//third_party/rust_crates:serde_json",
    "//third_party/rust_crates:tokio",
  ]

  sources = [
    "src/args.rs",
    "src/lib.rs",
  ]
}

ffx_tool("ffx_monitor") {
  # Needed for Honeydew's SDK inclusion
  #
  # TODO(b/330934833): Remove when IDK allows for `testonly` targets in dep
  # tree or when we can separate the concept of data_dep from host_test_data.
  testonly = false

  edition = "2024"
  output_name = "ffx-monitor"

  deps = [
    ":lib",
    "//src/developer/ffx/lib/fho:lib",
    "//src/lib/fuchsia-async",
  ]
  sources = [ "src/main.rs" ]
}

group("monitor") {
  public_deps = [
    ":ffx_monitor",
    ":ffx_monitor_host_tool",
  ]
}

group("bin") {
  public_deps = [ ":ffx_monitor_versioned" ]
}

group("tests") {
  testonly = true
  deps = [ ":lib_test($host_toolchain)" ]
}