src/developer/ffx/plugins/profile/stacktrack/BUILD.gn

# Copyright 2026 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//src/developer/ffx/build/ffx_plugin.gni")
import("//src/developer/ffx/lib/e2e_emu/ffx_e2e_test.gni")

if (is_host) {
  ffx_plugin("ffx_profile_stacktrack") {
    sdk_category = "not-yet-specified"
    version = "0.1.0"
    edition = "2024"

    args_sources = [ "src/args.rs" ]
    args_deps = [
      "//src/developer/ffx/core:lib",
      "//third_party/rust_crates:argh",
    ]

    sources = [ "src/lib.rs" ]
    deps = [
      "common:ffx_profile_stacktrack_common",
      "//sdk/fidl/fuchsia.memory.stacktrack.client:fuchsia.memory.stacktrack.client_rust_fdomain",
      "//src/developer/ffx/config:lib",
      "//src/developer/ffx/lib/fho:lib",
      "//src/developer/ffx/lib/target/holders:lib",
      "//src/developer/ffx/lib/writer:lib",
      "//src/lib/fdomain/client",
      "//src/performance/memory/stacktrack/lib/stacktrack_snapshot:stacktrack_snapshot_fdomain",
      "//third_party/rust_crates:anyhow",
      "//third_party/rust_crates:async-trait",
    ]
  }

  ffx_e2e_test("verify_ffx_profile_stacktrack") {
    testonly = true

    edition = "2024"
    source_root = "src/tests.rs"
    sources = [ source_root ]

    product_bundle = ":product_bundle"

    deps = [
      "//src/lib/fuchsia",
      "//src/lib/fuchsia-async",
      "//third_party/rust_crates:anyhow",
      "//third_party/rust_crates:log",
      "//third_party/rust_crates:serde",
      "//third_party/rust_crates:serde_json",
    ]
  }

  group("host_tests") {
    testonly = true
    deps = [
      ":verify_ffx_profile_stacktrack",
      "common:ffx_profile_stacktrack_common_test",
    ]
  }
}

ffx_e2e_product_bundle("product_bundle") {
  name = "profile_stacktrack_test"
  product_configuration = {
    platform = {
      build_type = "eng"
    }
    base_packages = [
      {
        package_target = "//src/performance/memory/stacktrack/example"
      },
    ]
  }
}