src/developer/ffx/plugins/audio/BUILD.gn

# Copyright 2022 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//src/developer/ffx/build/ffx_plugin.gni")
import("//src/developer/ffx/build/ffx_tool.gni")

ffx_plugin("ffx_audio") {
  sdk_category = "not-yet-specified"
  version = "0.1.0"
  edition = "2021"
  with_unit_tests = false

  args_deps = [
    "//src/developer/ffx/core:lib",
    "//third_party/rust_crates:argh",
  ]

  plugin_deps = [
    "device:ffx_audio_device",
    "gen:ffx_audio_gen",
    "list-devices:ffx_audio_listdevices",
    "play:ffx_audio_play",
    "record:ffx_audio_record",
  ]

  deps = [ "//src/developer/ffx/lib/errors:lib" ]

  args_sources = [ "src/args.rs" ]

  ## Uncomment this line, to enable all lints during local development.
  # configs = [ "//build/config/rust/lints:clippy_warn_all" ]
}

ffx_tool("ffx_audio_tool") {
  edition = "2021"
  output_name = "ffx-audio"
  deps = [
    ":ffx_audio_suite",
    "//src/lib/fuchsia-async",
  ]
  sources = [ "src/main.rs" ]

  sdk_target_name = "sdk"
  sdk_category = "partner"
}

group("audio") {
  public_deps = [
    ":ffx_audio_tool",
    ":ffx_audio_tool_host_tool",
  ]
}

group("bin") {
  public_deps = [ ":ffx_audio_tool_versioned" ]
}

group("tests") {
  testonly = true
  deps = [ ":ffx_audio_tests($host_toolchain)" ]
}