src/developer/console/test/BUILD.gn

# Copyright 2025 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.
import("//build/components.gni")
import("//build/rust/rustc_binary.gni")
import("//build/rust/rustc_test.gni")

rustc_test("developer_console_integration_test") {
  edition = "2024"
  sources = [ "src/lib.rs" ]

  deps = [
    "//sdk/fidl/fuchsia.component.resolution:fuchsia.component.resolution_rust",
    "//sdk/fidl/fuchsia.developer.console:fuchsia.developer.console_rust",
    "//sdk/fidl/fuchsia.io:fuchsia.io_rust",
    "//sdk/fidl/fuchsia.process:fuchsia.process_rust",
    "//sdk/rust/zx",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/storage/lib/vfs/rust:vfs",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:test-case",
  ]
  configs -= [ "//build/config/rust/lints:allow_unused_results" ]
  configs += [ "//build/config/rust/lints:clippy_warn_all" ]
}

rustc_binary("developer_console_integration_test_support_bin") {
  edition = "2024"
  sources = [ "src/support.rs" ]
  source_root = "src/support.rs"
  deps = [
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/lib/fuchsia-fs",
    "//src/storage/lib/vfs/rust:vfs",
    "//third_party/rust_crates:argh",
    "//third_party/rust_crates:futures",
  ]
  configs -= [ "//build/config/rust/lints:allow_unused_results" ]
  configs += [ "//build/config/rust/lints:clippy_warn_all" ]
}

fuchsia_component("developer-console-test-support") {
  manifest = "meta/developer-console-test-support.cml"
  deps = [
    ":developer_console_integration_test_support_bin",
    "//zircon/third_party/uapp/dash",
  ]
}

fuchsia_unittest_package("developer-console-integration-test") {
  manifest = "meta/developer-console-integration-test.cml"
  restricted_features = [ "use_dictionaries" ]
  deps = [
    ":developer-console-test-support",
    ":developer_console_integration_test",
    "//src/bringup/bin/ptysvc:component",
    "//src/developer/console:component",
  ]
}