src/developer/console/BUILD.gn

# Copyright 2025 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_binary.gni")

rustc_binary("launcher_bin") {
  output_name = "developer-console"
  edition = "2024"

  sources = [
    "src/error.rs",
    "src/io.rs",
    "src/main.rs",
    "src/namespace.rs",
    "src/process.rs",
    "src/program.rs",
    "src/util.rs",
  ]
  deps = [
    "//sdk/fidl/fuchsia.component.runner:fuchsia.component.runner_rust",
    "//sdk/fidl/fuchsia.developer.console:fuchsia.developer.console_rust",
    "//sdk/fidl/fuchsia.device:fuchsia.device_rust",
    "//sdk/fidl/fuchsia.hardware.pty:fuchsia.hardware.pty_rust",
    "//sdk/fidl/fuchsia.io:fuchsia.io_rust",
    "//sdk/fidl/fuchsia.process:fuchsia.process_rust",
    "//sdk/fidl/fuchsia.sys2:fuchsia.sys2_rust",
    "//sdk/rust/zx",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/lib/fuchsia-fs",
    "//src/lib/fuchsia-runtime",
    "//src/sys/lib/library_loader",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:log",
    "//third_party/rust_crates:thiserror",
  ]

  configs -= [ "//build/config/rust/lints:allow_unused_results" ]
  configs += [
    "//build/config/rust/lints:clippy_warn_all",
    "//build/config/rust:bootfs",
  ]
}

fuchsia_component("component") {
  component_name = "developer-console"
  manifest = "meta/developer-console.cml"
  deps = [ ":launcher_bin" ]
}

fuchsia_package("package") {
  package_name = "developer-console"
  deps = [ ":component" ]
}

group("console") {
  deps = [ ":package" ]
}

group("tests") {
  testonly = true
  deps = [ "test:developer-console-integration-test" ]
}