src/connectivity/network/drivers/network-device/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/components.gni")
import("//build/drivers.gni")
import("//build/test.gni")

driver_bind_rules("network-device_bind") {
  rules = "meta/network_device.bind"
  bind_output = "network-device.bindbc"
  tests = "meta/bind-tests.json"
  deps = [
    "//sdk/fidl/fuchsia.hardware.network.driver:fuchsia.hardware.network.driver_bindlib",
    "//src/devices/bind/fuchsia.network",
  ]
}

source_set("src") {
  sources = [
    "network_device.cc",
    "network_device.h",
  ]
  public_deps = [
    ":network-device_bind",
    "device:device_driver",
    "//sdk/fidl/fuchsia.hardware.network.driver:fuchsia.hardware.network.driver_cpp",
    "//sdk/lib/driver/component/cpp",
    "//sdk/lib/driver/devfs/cpp",
    "//src/devices/lib/driver:driver_runtime",
  ]
}

fuchsia_cc_driver("network-device-driver") {
  output_name = "network-device"
  configs += [ "//build/config/fuchsia:enable_zircon_asserts" ]

  deps = [ ":src" ]
}

fuchsia_driver_component("network-device") {
  visibility = [
    ":*",
    "//src/connectivity/ethernet/drivers/asix-88179:*",
    "//src/connectivity/ethernet/drivers/usb-cdc-ecm:*",
    "//src/connectivity/network:drivers",
    "//src/connectivity/network/drivers",
    "//src/connectivity/wlan/tests/helpers/realm-factory:*",
  ]
  component_name = "network-device"
  deps = [ ":network-device-driver" ]
  info = "meta/network-device-info.json"
  manifest = "meta/network-device.cml"
}

fuchsia_driver_package("package") {
  package_name = "network-device"
  driver_components = [ ":network-device" ]
}

group("tests") {
  testonly = true

  deps = [
    ":network-device-test",
    ":network-device_bind_test",
    "device:tests",
    "mac:tests",
  ]
}

test("driver-test") {
  output_name = "network-device-test"
  sources = [ "network_device_test.cc" ]
  deps = [
    ":src",
    "device:test_util_driver",
    "mac:test_util_driver",
    "//sdk/lib/driver/testing/cpp",
    "//src/lib/fxl/test:gtest_main",
    "//src/lib/testing/predicates",
    "//zircon/system/ulib/zx",
  ]
}

fuchsia_unittest_package("network-device-test") {
  deps = [ ":driver-test" ]
}