src/connectivity/ethernet/drivers/rndis-function/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/components.gni")
import("//build/drivers.gni")
import("//build/test.gni")

driver_bind_rules("rndis_function_bind") {
  rules = "meta/rndis_function.bind"
  bind_output = "rndis-function.bindbc"
  tests = "meta/bind-tests.json"
  deps = [
    "//src/devices/bind/fuchsia.usb",
    "//src/devices/bind/fuchsia.usb.misc",
  ]
}

source_set("common") {
  configs += [ "//build/config:all_source" ]
  sources = [
    "rndis_function.cc",
    "rndis_function.h",
  ]
  deps = [ "//sdk/lib/driver/metadata/cpp" ]
  public_deps = [
    ":rndis_function_bind",
    "//sdk/banjo/fuchsia.hardware.ethernet:fuchsia.hardware.ethernet_banjo_cpp",
    "//sdk/banjo/fuchsia.hardware.usb:fuchsia.hardware.usb_banjo_cpp",
    "//sdk/banjo/fuchsia.hardware.usb.composite:fuchsia.hardware.usb.composite_banjo_cpp",
    "//sdk/banjo/fuchsia.hardware.usb.function:fuchsia.hardware.usb.function_banjo_cpp",
    "//sdk/banjo/fuchsia.hardware.usb.request:fuchsia.hardware.usb.request_banjo_cpp",
    "//sdk/fidl/fuchsia.boot.metadata:fuchsia.boot.metadata_cpp",
    "//sdk/lib/async",
    "//sdk/lib/async:async-cpp",
    "//sdk/lib/async-loop:async-loop-cpp",
    "//sdk/lib/async-loop:async-loop-default",
    "//sdk/lib/driver/compat/cpp",
    "//sdk/lib/driver/component/cpp",
    "//src/connectivity/ethernet/lib/rndis",
    "//src/devices/usb/lib/usb:cdc",
    "//src/devices/usb/lib/usb:usb-dfv2-compat-logging",
    "//zircon/system/ulib/fbl",
  ]
}

fuchsia_cc_driver("rndis-function-driver") {
  # visibility = [ ":*" ]
  output_name = "rndis-function"

  configs += [
    "//build/config:all_source",
    "//build/config/fuchsia:enable_zircon_asserts",
  ]
  deps = [
    ":common",
    "//src/devices/lib/driver",
  ]
}

fuchsia_driver_component("rndis-function") {
  component_name = "rndis-function"
  deps = [ ":rndis-function-driver" ]
  info = "meta/rndis-function-info.json"
  manifest = "meta/rndis-function.cml"
}

fuchsia_driver_package("package") {
  package_name = "rndis-function"
  driver_components = [ ":rndis-function" ]
}

test("rndis-function-test") {
  if (is_fuchsia) {
    testonly = true
  }
  sources = [ "rndis_function_test.cc" ]
  deps = [
    ":common",
    "//sdk/fidl/fuchsia.boot.metadata:fuchsia.boot.metadata_cpp",
    "//sdk/lib/driver/metadata/cpp",
    "//sdk/lib/driver/testing/cpp",
    "//src/lib/fxl/test:gtest_main",
    "//src/lib/testing/predicates",
  ]
}

fuchsia_unittest_package("rndis-function-test-package") {
  package_name = "rndis-function-test"
  deps = [ ":rndis-function-test" ]

  # There's expected error logs that happen in some test cases.
  test_specs = {
    log_settings = {
      max_severity = "ERROR"
    }
  }
}

group("tests") {
  testonly = true
  deps = [
    ":rndis-function-test-package",
    ":rndis_function_bind_test",
  ]
}