sdk/lib/driver/metadata/cpp/tests/metadata_integration_test/BUILD.gn

# Copyright 2024 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD_style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/components.gni")
import("//build/drivers.gni")
import("//build/test.gni")

group("tests") {
  testonly = true
  deps = [ ":metadata_integration_test" ]
}

bind_library("fuchsia_driver_metadata_test_bind_library") {
  testonly = true
  source = "fuchsia.driver.metadata.test.bind"
  public_deps = [ "//src/devices/bind/fuchsia.test" ]
}

test("metadata_integration_test_bin") {
  testonly = true
  output_name = "metadata_integration_test"
  sources = [ "metadata_integration_test.cc" ]

  deps = [
    "//sdk/fidl/fuchsia.driver.test:fuchsia.driver.test_cpp",
    "//sdk/lib/device-watcher/cpp",
    "//sdk/lib/driver/metadata/cpp",
    "//sdk/lib/driver/metadata/cpp/tests/fuchsia.hardware.test:fuchsia.hardware.test_cpp",
    "//sdk/lib/driver_test_realm/realm_builder/cpp",
    "//src/lib/fxl/test:gtest_main",
    "//src/lib/testing/loop_fixture",
    "//src/lib/testing/predicates",
  ]
}

fuchsia_unittest_package("metadata_integration_test") {
  test_specs = {
    log_settings = {
      max_severity = "ERROR"
    }
  }
  deps = [
    ":metadata_integration_test_bin",
    "metadata_forwarder_test_driver:component",
    "metadata_retriever_test_driver:no_use_component",
    "metadata_retriever_test_driver:use_component",
    "metadata_sender_test_driver:expose_component",
    "metadata_sender_test_driver:no_expose_component",
    "test_root:component",
  ]
}