sdk/lib/driver/component/cpp/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/cpp/sdk_source_set.gni")
import("//build/testing/cc_test_executable.gni")

group("tests") {
  testonly = true
  deps = [ ":driver-component-cpp-tests" ]
}

# This library is available on Fuchsia API level 15 and above.
sdk_source_set("cpp") {
  category = "partner"
  sdk_name = "driver_component_cpp"
  stable = true

  include_base = "//sdk"
  public_configs = [ "//sdk/config" ]

  sources = [
    "completer.cc",
    "composite_node_spec.h",
    "driver_base.cc",
    "driver_base.h",
    "driver_export.h",
    "internal/driver_server.h",
    "internal/start_args.h",
    "internal/symbols.h",
    "node_add_args.cc",
    "node_add_args.h",
    "prepare_stop_completer.h",
    "start_completer.h",
  ]

  sdk_headers_for_internal_use = [
    "internal/driver_server.h",
    "internal/start_args.h",
    "internal/symbols.h",
  ]

  public_deps = [
    "//sdk/fidl/fuchsia.component.decl:fuchsia.component.decl_cpp",
    "//sdk/fidl/fuchsia.driver.framework:fuchsia.driver.framework_cpp",
    "//sdk/lib/driver/incoming/cpp",
    "//sdk/lib/driver/logging/cpp",
    "//sdk/lib/driver/node/cpp",
    "//sdk/lib/driver/outgoing/cpp",
    "//sdk/lib/driver/runtime:driver_runtime_cpp",
    "//sdk/lib/driver/symbols",
    "//sdk/lib/fidl",
    "//sdk/lib/fidl_driver",
    "//sdk/lib/inspect/component/cpp",
    "//sdk/lib/stdcompat",
  ]
}

source_set("test_base") {
  sources = [
    "tests/test_base.cc",
    "tests/test_base.h",
  ]

  public_deps = [
    ":cpp",
    "//sdk/fidl/fuchsia.io:fuchsia.io_hlcpp",
    "//sdk/lib/fit-promise",
  ]
}

cc_test_executable("cpp_test") {
  testonly = true
  sources = [
    "tests/driver_base_test.cc",
    "tests/driver_fidl_test.cc",
    "tests/fixture_based_tests.cc",
    "tests/logger_test.cc",
    "tests/namespace_test.cc",
    "tests/node_add_args_test.cc",
    "tests/start_args_test.cc",
    "tests/test_driver.cc",
    "tests/test_driver.h",
  ]

  deps = [
    ":cpp",
    ":test_base",
    "tests/fidl:fuchsia.driver.component.test_cpp",
    "//sdk/fidl/fuchsia.device.fs:fuchsia.device.fs_hlcpp",
    "//sdk/fidl/fuchsia.io:fuchsia.io_hlcpp",
    "//sdk/lib/async-loop:async-loop-cpp",
    "//sdk/lib/async-loop:async-loop-default",
    "//sdk/lib/async_patterns/testing/cpp",
    "//sdk/lib/component/outgoing/cpp",
    "//sdk/lib/driver/compat/cpp",
    "//sdk/lib/driver/devfs/cpp",
    "//sdk/lib/driver/runtime:driver_runtime_cpp",
    "//sdk/lib/driver/testing/cpp",
    "//sdk/lib/driver/testing/cpp:minimal_compat_environment",
    "//src/devices/lib/driver:driver_runtime",
    "//src/lib/diagnostics/fake-log-sink/cpp",
    "//src/lib/fxl/test:gtest_main",
    "//src/lib/testing/loop_fixture",
    "//src/lib/testing/predicates",
    "//third_party/googletest:gmock",
    "//zircon/system/ulib/zx",
  ]

  # TODO(https://fxbug.dev/42176699): This target uses mutable tables which are deprecated,
  # rather than builders.
  configs += [ "//build/cpp:fidl-wire-deprecated-mutable-tables" ]
}

fuchsia_unittest_package("driver-component-cpp-tests") {
  manifest = "meta/cpp_test.cml"
  deps = [ ":cpp_test" ]
}