scripts/lib/agents/BUILD.gn

# Copyright 2026 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/host.gni")
import("//build/python/python_host_test.gni")
import("//build/python/python_library.gni")
import("//build/testing/python_build_time_tests.gni")

group("tests") {
  testonly = true

  deps = [
    ":agents_source_path_test($host_toolchain)",
    ":agents_tests($host_toolchain)",
  ]
}

if (is_host) {
  python_library("agents") {
    sources = [
      "__init__.py",
      "agents.py",
    ]
    data_package_name = "data"
    data_sources = [ "//tools/devshell/lib/agents.txt" ]
  }

  python_build_time_tests("agents_source_path_test") {
    tests = [ "tests/agents_test.py" ]
    inputs = [ "//tools/devshell/lib/agents.txt" ]
    deps = [ ":agents" ]
  }

  python_host_test("agents_tests") {
    main_source = "tests/agents_test.py"
    main_callable = "unittest.main"
    libraries = [ ":agents" ]
  }
}