examples/fidl/new/key_value_store/baseline/rust/BUILD.gn

# Copyright 2022 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")

# The two definitions below are Fuchsia components, which will be wrapped into a package for
# delivery to running devices.
fuchsia_component("client") {
  component_name = "keyvaluestore_baseline_client"
  manifest = "//examples/fidl/new/key_value_store/baseline/meta/client.cml"
  deps = [
    "client:bin",
    "//examples/fidl/new/key_value_store/data:resources",
  ]
}
fuchsia_component("server") {
  component_name = "keyvaluestore_baseline_server"
  manifest = "//examples/fidl/new/key_value_store/baseline/meta/server.cml"
  deps = [ "server:bin" ]
}

# The Fuchsia package, containing all of our child components in one neat artifact.
fuchsia_package("examples_fidl_keyvaluestore_baseline_rust") {
  deps = [
    ":client",
    ":server",
    "//examples/fidl/new/key_value_store/baseline:client_config_values",
  ]
}

# The following is an internal test harness for validating this example. It is not part of the
# example itself, and exists as a validation method to ensure that the code does not go stale.
fuchsia_component("test") {
  testonly = true
  manifest = "//examples/fidl/new/key_value_store/baseline/test/meta/runner.cml"
  deps = [
    "//examples/fidl/new/key_value_store/baseline/test:runner_bin",
    "//examples/fidl/new/key_value_store/baseline/test/goldens:resources",
  ]
}
fuchsia_test_package("examples_fidl_keyvaluestore_baseline_rust_tests") {
  deps = [
    ":client",
    ":server",
    "//examples/fidl/new/key_value_store/baseline:client_config_values",
    "//examples/fidl/new/key_value_store/baseline/realm",
  ]
  test_components = [ ":test" ]
}
group("tests") {
  testonly = true
  deps = [ ":examples_fidl_keyvaluestore_baseline_rust_tests" ]
}