src/graphics/display/drivers/display/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/config/fuchsia/rules.gni")

bind_rules("display_bind") {
  rules = "display.bind"
  output = "display-bind.h"
  tests = "bind_tests.json"
  deps = [ "//src/devices/bind/fuchsia.hardware.display" ]
}

driver_module("display") {
  configs += [
    "//build/config:all_source",
    "//build/config/fuchsia:enable_zircon_asserts",
  ]
  configs += [ "//build/unification/config:zircon-migrated" ]
  deps = [
    ":shared",
    "//sdk/lib/syslog/cpp:backend_legacy",
    "//src/devices/lib/driver",
  ]
}

# Also used by test/.
source_set("shared") {
  visibility = [
    "../fake:fake-display-device-tree",
    "./*",
  ]
  configs += [ "//build/config:all_source" ]
  sources = [
    "client.cc",
    "controller.cc",
    "eld.cc",
    "fence.cc",
    "image.cc",
    "layer.cc",
  ]
  public_deps = [
    ":display_bind",
    "//sdk/banjo/fuchsia.hardware.audiotypes",
    "//sdk/banjo/fuchsia.hardware.display.capture",
    "//sdk/banjo/fuchsia.hardware.display.clamprgb",
    "//sdk/banjo/fuchsia.hardware.display.controller",
    "//sdk/banjo/fuchsia.hardware.i2cimpl",
    "//sdk/fidl/fuchsia.hardware.display:fuchsia.hardware.display_llcpp",
    "//sdk/fidl/fuchsia.sysmem:fuchsia.sysmem_c",
    "//sdk/fidl/fuchsia.sysmem:fuchsia.sysmem_llcpp",
    "//src/devices/lib/audio",
    "//src/devices/lib/mmio",
    "//src/lib/ddk",
    "//src/lib/ddktl",
    "//src/lib/eld",
    "//src/lib/fsl",
    "//zircon/public/lib/async-cpp",
    "//zircon/public/lib/fbl",
    "//zircon/public/lib/fidl",
    "//zircon/public/lib/hwreg",
    "//zircon/public/lib/sync",
    "//zircon/public/lib/zx",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
    "//zircon/system/ulib/audio-proto-utils",
    "//zircon/system/ulib/edid",
    "//zircon/system/ulib/fidl-utils",
    "//zircon/system/ulib/image-format:image-format-llcpp",
    "//zircon/system/ulib/inspect",
    "//zircon/system/ulib/trace:trace-driver",
  ]

  # TODO(fxbug.dev/58162): delete the below and fix compiler warnings
  configs += [ "//build/config:Wno-conversion" ]
}

source_set("preferred-scanout-image-type") {
  sources = [ "preferred-scanout-image-type.h" ]
}

group("tests") {
  testonly = true
  deps = [
    ":display_bind_test",
    "tests",
  ]
}