build/flutter/config.gni

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/flutter/flutter_build_config.gni")

declare_args() {
  # If set to true, will force the runenrs to be built in
  # product mode which means they will not have an exposed vm service
  flutter_force_product = false
}

declare_args() {
  if (flutter_force_product) {
    # Product AOT
    flutter_default_build_cfg = flutter_release_build_cfg
  } else if (is_debug) {
    # Non-product JIT
    flutter_default_build_cfg = flutter_debug_build_cfg
  } else {
    # Non-product AOT
    # flutter_default_build_cfg = flutter_profile_build_cfg
    # TODO(fxbug.dev/67583) Disabling aot builds until this crash
    # is resolved. This is not the flutter_debug_build_cfg because it
    # does not enable asserts.
    flutter_default_build_cfg = {
      runtime_meta = "//build/flutter/meta/jit_runtime"
      runner_dep = "//src/flutter:flutter_jit_runner"
      platform_name = "flutter_runner"
      is_aot = false
      is_product = false
      enable_asserts = false
    }
  }
}