zircon/system/utest/platform-bus/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

##########################################
# Though under //zircon, this build file #
# is meant to be used in the Fuchsia GN  #
# build.                                 #
# See fxb/36139.                         #
##########################################

assert(!defined(zx) || zx != "/",
       "This file can only be used in the Fuchsia GN build.")

import("//build/config/fuchsia/rules.gni")
import("//build/test.gni")
import("//build/unification/images/migrated_manifest.gni")

test("platform-bus") {
  # Dependent manifests unfortunately cannot be marked as `testonly`.
  # TODO(44278): Remove when converting this file to proper GN build idioms.
  testonly = false
  configs += [ "//build/unification/config:zircon-migrated" ]
  sources = [ "main.cc" ]
  deps = [
    "//zircon/public/lib/ddk",
    "//zircon/public/lib/devmgr-integration-test",
    "//zircon/public/lib/devmgr-launcher",
    "//zircon/public/lib/fbl",
    "//zircon/public/lib/fdio",
    "//zircon/public/lib/libzbi",
    "//zircon/public/lib/zx",
    "//zircon/public/lib/zxtest",
    "//zircon/system/fidl/fuchsia-sysinfo:llcpp",
  ]
}

simple_drivers = [
  "child-1",
  "child-2",
  "child-2.proxy",
  "child-3",
  "parent",
  "composite",
]

group("test") {
  testonly = false
  deps = [
    ":test-audio-codec",
    ":test-board",
    ":test-clock",
    ":test-gpio",
    ":test-i2c",
    ":test-power",
    ":test-pwm",
    ":test-spi",
  ]
  foreach(driver, simple_drivers) {
    deps += [ ":test-$driver" ]
  }
}

driver_module("test-board") {
  defines = [ "_ALL_SOURCE" ]
  configs += [ "//build/config/fuchsia:enable_zircon_asserts" ]
  configs -= [ "//build/config/fuchsia:no_cpp_standard_library" ]
  configs += [ "//build/config/fuchsia:static_cpp_standard_library" ]
  configs += [ "//build/unification/config:zircon-migrated" ]
  sources = [
    "test-audio-codec.cc",
    "test-board.cc",
    "test-clock.cc",
    "test-gpio.cc",
    "test-i2c.cc",
    "test-power.cc",
    "test-pwm.cc",
    "test-spi.cc",
    "test.cc",
  ]
  deps = [
    "//src/devices/lib/driver",
    "//zircon/public/lib/amlogic",
    "//zircon/public/lib/ddk",
    "//zircon/public/lib/ddktl",
    "//zircon/public/lib/fbl",
    "//zircon/system/banjo/ddk.protocol.platform.bus",
    "//zircon/system/banjo/ddk.protocol.platform.device",
  ]
}

driver_module("test-gpio") {
  defines = [ "_ALL_SOURCE" ]
  configs += [ "//build/config/fuchsia:enable_zircon_asserts" ]
  configs -= [ "//build/config/fuchsia:no_cpp_standard_library" ]
  configs += [ "//build/config/fuchsia:static_cpp_standard_library" ]
  configs += [ "//build/unification/config:zircon-migrated" ]
  sources = [ "test/gpio.cc" ]
  deps = [
    "//src/devices/lib/driver",
    "//zircon/public/lib/ddk",
    "//zircon/public/lib/ddktl",
    "//zircon/public/lib/fbl",
    "//zircon/public/lib/zx",
    "//zircon/system/banjo/ddk.protocol.gpio",
    "//zircon/system/banjo/ddk.protocol.gpioimpl",
    "//zircon/system/banjo/ddk.protocol.platform.bus",
    "//zircon/system/banjo/ddk.protocol.platform.device",
  ]
}

driver_module("test-power") {
  defines = [ "_ALL_SOURCE" ]
  configs += [ "//build/config/fuchsia:enable_zircon_asserts" ]
  configs -= [ "//build/config/fuchsia:no_cpp_standard_library" ]
  configs += [ "//build/config/fuchsia:static_cpp_standard_library" ]
  configs += [ "//build/unification/config:zircon-migrated" ]
  sources = [ "test/power.cc" ]
  deps = [
    "//src/devices/lib/driver",
    "//zircon/public/lib/ddk",
    "//zircon/public/lib/ddktl",
    "//zircon/public/lib/fbl",
    "//zircon/public/lib/zx",
    "//zircon/system/banjo/ddk.protocol.platform.bus",
    "//zircon/system/banjo/ddk.protocol.platform.device",
    "//zircon/system/banjo/ddk.protocol.power",
    "//zircon/system/banjo/ddk.protocol.powerimpl",
  ]
}

driver_module("test-clock") {
  defines = [ "_ALL_SOURCE" ]
  configs += [ "//build/config/fuchsia:enable_zircon_asserts" ]
  configs -= [ "//build/config/fuchsia:no_cpp_standard_library" ]
  configs += [ "//build/config/fuchsia:static_cpp_standard_library" ]
  configs += [ "//build/unification/config:zircon-migrated" ]
  sources = [ "test/clock.cc" ]
  deps = [
    "//src/devices/lib/driver",
    "//zircon/public/lib/ddk",
    "//zircon/public/lib/ddktl",
    "//zircon/public/lib/fbl",
    "//zircon/public/lib/zx",
    "//zircon/system/banjo/ddk.protocol.clock",
    "//zircon/system/banjo/ddk.protocol.clockimpl",
    "//zircon/system/banjo/ddk.protocol.platform.bus",
    "//zircon/system/banjo/ddk.protocol.platform.device",
  ]
}

driver_module("test-i2c") {
  defines = [ "_ALL_SOURCE" ]
  configs += [ "//build/config/fuchsia:enable_zircon_asserts" ]
  configs -= [ "//build/config/fuchsia:no_cpp_standard_library" ]
  configs += [ "//build/config/fuchsia:static_cpp_standard_library" ]
  configs += [ "//build/unification/config:zircon-migrated" ]
  sources = [ "test/i2c.cc" ]
  deps = [
    "//sdk/banjo/ddk.protocol.i2cimpl",
    "//src/devices/lib/driver",
    "//zircon/public/lib/ddk",
    "//zircon/public/lib/ddktl",
    "//zircon/public/lib/fbl",
    "//zircon/public/lib/zx",
    "//zircon/system/banjo/ddk.protocol.i2c",
    "//zircon/system/banjo/ddk.protocol.platform.bus",
    "//zircon/system/banjo/ddk.protocol.platform.device",
  ]
}

driver_module("test-spi") {
  defines = [ "_ALL_SOURCE" ]
  configs += [ "//build/config/fuchsia:enable_zircon_asserts" ]
  configs -= [ "//build/config/fuchsia:no_cpp_standard_library" ]
  configs += [ "//build/config/fuchsia:static_cpp_standard_library" ]
  configs += [ "//build/unification/config:zircon-migrated" ]
  sources = [ "test/spi.cc" ]
  deps = [
    "//sdk/banjo/ddk.protocol.spiimpl",
    "//src/devices/lib/driver",
    "//zircon/public/lib/ddk",
    "//zircon/public/lib/ddktl",
    "//zircon/public/lib/fbl",
    "//zircon/public/lib/zx",
    "//zircon/system/banjo/ddk.protocol.platform.bus",
    "//zircon/system/banjo/ddk.protocol.platform.device",
    "//zircon/system/banjo/ddk.protocol.spi",
  ]
}

driver_module("test-audio-codec") {
  defines = [ "_ALL_SOURCE" ]
  configs += [ "//build/config/fuchsia:enable_zircon_asserts" ]
  configs -= [ "//build/config/fuchsia:no_cpp_standard_library" ]
  configs += [ "//build/config/fuchsia:static_cpp_standard_library" ]
  configs += [ "//build/unification/config:zircon-migrated" ]
  sources = [ "test/audio-codec.cc" ]
  deps = [
    "//src/devices/lib/driver",
    "//zircon/public/lib/ddk",
    "//zircon/public/lib/ddktl",
    "//zircon/public/lib/fbl",
    "//zircon/public/lib/zx",
    "//zircon/system/banjo/ddk.protocol.codec",
    "//zircon/system/banjo/ddk.protocol.platform.bus",
    "//zircon/system/banjo/ddk.protocol.platform.device",
  ]
}

driver_module("test-pwm") {
  defines = [ "_ALL_SOURCE" ]
  configs += [ "//build/config/fuchsia:enable_zircon_asserts" ]
  configs -= [ "//build/config/fuchsia:no_cpp_standard_library" ]
  configs += [ "//build/config/fuchsia:static_cpp_standard_library" ]
  configs += [ "//build/unification/config:zircon-migrated" ]
  sources = [ "test/pwm.cc" ]
  deps = [
    "//src/devices/lib/driver",
    "//zircon/public/lib/ddk",
    "//zircon/public/lib/ddktl",
    "//zircon/public/lib/fbl",
    "//zircon/public/lib/zx",
    "//zircon/system/banjo/ddk.protocol.platform.bus",
    "//zircon/system/banjo/ddk.protocol.platform.device",
    "//zircon/system/banjo/ddk.protocol.pwm",
  ]
}

foreach(driver, simple_drivers) {
  driver_module("test-$driver") {
    defines = [ "_ALL_SOURCE" ]
    configs += [ "//build/config/fuchsia:enable_zircon_asserts" ]
    configs -= [ "//build/config/fuchsia:no_cpp_standard_library" ]
    configs += [ "//build/config/fuchsia:static_cpp_standard_library" ]
    configs += [ "//build/unification/config:zircon-migrated" ]
    sources = [ "test/$driver.c" ]
    deps = [
      "//sdk/banjo/ddk.protocol.composite",
      "//src/devices/lib/driver",
      "//zircon/public/lib/ddk",
      "//zircon/public/lib/device-protocol-i2c",
      "//zircon/public/lib/sync",
      "//zircon/system/banjo/ddk.protocol.clock",
      "//zircon/system/banjo/ddk.protocol.codec",
      "//zircon/system/banjo/ddk.protocol.gpio",
      "//zircon/system/banjo/ddk.protocol.i2c",
      "//zircon/system/banjo/ddk.protocol.platform.device",
      "//zircon/system/banjo/ddk.protocol.power",
      "//zircon/system/banjo/ddk.protocol.pwm",
      "//zircon/system/banjo/ddk.protocol.spi",
    ]
  }

  migrated_manifest("test-$driver-manifest") {
    deps = [ ":test-$driver" ]
  }
}

migrated_manifest("platform-bus-manifest") {
  deps = [ ":platform-bus" ]
}

migrated_manifest("test-board-manifest") {
  deps = [ ":test-board" ]
}

migrated_manifest("test-gpio-manifest") {
  deps = [ ":test-gpio" ]
}

migrated_manifest("test-power-manifest") {
  deps = [ ":test-power" ]
}

migrated_manifest("test-clock-manifest") {
  deps = [ ":test-clock" ]
}

migrated_manifest("test-i2c-manifest") {
  deps = [ ":test-i2c" ]
}

migrated_manifest("test-spi-manifest") {
  deps = [ ":test-spi" ]
}

migrated_manifest("test-audio-codec-manifest") {
  deps = [ ":test-audio-codec" ]
}

migrated_manifest("test-pwm-manifest") {
  deps = [ ":test-pwm" ]
}