zircon/system/utest/fidl-llcpp-interop/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

##########################################
# Though under //zircon, this build file #
# is meant to be used in the Fuchsia GN  #
# build.                                 #
# See fxb/36139.                         #
##########################################

assert(!defined(zx) || zx != "/",
       "This file can only be used in the Fuchsia GN build.")

import("//build/fidl/fidl.gni")
import("//build/test.gni")
import("//build/unification/images/migrated_manifest.gni")

test("fidl-llcpp-interop") {
  # Dependent manifests unfortunately cannot be marked as `testonly`.
  # TODO(44278): Remove when converting this file to proper GN build idioms.
  if (is_fuchsia) {
    testonly = false
  }
  if (is_fuchsia) {
    configs += [ "//build/unification/config:zircon-migrated" ]
  }
  if (is_fuchsia) {
    fdio_config = [ "//build/config/fuchsia:fdio_config" ]
    if (configs + fdio_config - fdio_config != configs) {
      configs -= fdio_config
    }
  }
  sources = [
    "basictypes_tests.cc",
    "controlflow_tests.cc",
    "dirent_tests.cc",
  ]
  deps = [
    ":fidl.test.llcpp.basictypes_c",
    ":fidl.test.llcpp.basictypes_llcpp",
    ":fidl.test.llcpp.controlflow_c",
    ":fidl.test.llcpp.controlflow_llcpp",
    ":fidl.test.llcpp.dirent_c",
    ":fidl.test.llcpp.dirent_llcpp",
    "//zircon/public/lib/async-cpp",
    "//zircon/public/lib/async-default",
    "//zircon/public/lib/async-loop-cpp",
    "//zircon/public/lib/async-loop-default",
    "//zircon/public/lib/fbl",
    "//zircon/public/lib/fdio",
    "//zircon/public/lib/fidl",
    "//zircon/public/lib/fidl-async",
    "//zircon/public/lib/fidl-async-cpp",
    "//zircon/public/lib/fidl-llcpp",
    "//zircon/public/lib/fidl-utils",
    "//zircon/public/lib/zx",
    "//zircon/public/lib/zxtest",
  ]
}

migrated_manifest("fidl-llcpp-interop-manifest") {
  deps = [ ":fidl-llcpp-interop" ]
}

fidl("fidl.test.llcpp.basictypes") {
  visibility = [ ":*" ]
  sources = [ "basictypes.test.fidl" ]

  # TODO(fxb/35879): Remove lint exclusions by fixing known FIDL lint violations in this target
  excluded_checks = [ "too-many-nested-libraries" ]
}

fidl("fidl.test.llcpp.controlflow") {
  visibility = [ ":*" ]
  sources = [ "controlflow.fidl" ]

  # TODO(fxb/35879): Remove lint exclusions by fixing known FIDL lint violations in this target
  excluded_checks = [ "too-many-nested-libraries" ]
}

fidl("fidl.test.llcpp.dirent") {
  visibility = [ ":*" ]
  sources = [ "dirent.fidl" ]

  # TODO(fxb/35879): Remove lint exclusions by fixing known FIDL lint violations in this target
  excluded_checks = [ "too-many-nested-libraries" ]
}