src/ui/input/drivers/hid-buttons/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/fuchsia/rules.gni")
import("//build/test.gni")
import("//build/test/test_package.gni")
import("//build/unification/images/migrated_manifest.gni")

driver_module("hid-buttons") {
  defines = [ "_ALL_SOURCE" ]
  configs += [ "//build/config/fuchsia:enable_zircon_asserts" ]
  configs -= [ "//build/config/fuchsia:no_cpp_standard_library" ]
  configs += [ "//build/config/fuchsia:static_cpp_standard_library" ]
  configs += [ "//build/unification/config:zircon-migrated" ]
  sources = []
  deps = [
    ":common",
    "//src/devices/lib/driver",
  ]
}

source_set("common") {
  defines = [ "_ALL_SOURCE" ]
  sources = [ "hid-buttons.cc" ]

  public_deps = [
    "//sdk/banjo/ddk.protocol.composite",
    "//sdk/fidl/fuchsia.buttons:fuchsia.buttons_llcpp",
    "//zircon/public/lib/async-cpp",
    "//zircon/public/lib/async-loop-cpp",
    "//zircon/public/lib/async-loop-default",
    "//zircon/public/lib/ddk",
    "//zircon/public/lib/ddktl",
    "//zircon/public/lib/fbl",
    "//zircon/public/lib/fidl-async-cpp",
    "//zircon/public/lib/hid",
    "//zircon/public/lib/sync",
    "//zircon/public/lib/zircon-internal",
    "//zircon/public/lib/zx",
    "//zircon/system/banjo/ddk.protocol.buttons",
    "//zircon/system/banjo/ddk.protocol.gpio",
    "//zircon/system/banjo/ddk.protocol.hidbus",
  ]
}

test("hid-buttons-test") {
  defines = [ "_ALL_SOURCE" ]
  configs += [ "//build/unification/config:zircon-migrated" ]
  output_name = "hid-buttons-test"
  sources = [ "hid-buttons-test.cc" ]
  deps = [
    ":common",
    "//zircon/public/lib/fake_ddk",
    "//zircon/public/lib/mock-function",
    "//zircon/public/lib/zxtest",
    "//zircon/system/banjo/ddk.protocol.gpio:ddk.protocol.gpio_mock",
  ]

  # TODO(47441): Fix the leaks and remove this.
  deps += [ "//build/config/sanitizers:suppress-lsan.DO-NOT-USE-THIS" ]
}

migrated_manifest("hid-buttons-manifest") {
  deps = [ ":hid-buttons" ]
}

unittest_package("hid-buttons-test-package") {
  package_name = "hid-buttons-test"
  deps = [ ":hid-buttons-test" ]

  tests = [
    {
      name = "hid-buttons-test"
      environments = basic_envs
    },
  ]
}
group("tests") {
  testonly = true
  deps = [ ":hid-buttons-test-package" ]
}