src/sys/test_adapters/gtest/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/package.gni")
import("//build/rust/rustc_binary.gni")
import("//build/test.gni")
import("//build/test/test_package.gni")

rustc_binary("bin") {
  testonly = true
  name = "gtest_adapter"
  with_unit_tests = true
  edition = "2018"

  deps = [
    "//sdk/fidl/fuchsia.test:fuchsia.test-rustc",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/lib/syslog/rust:syslog",
    "//src/lib/zircon/rust:fuchsia-zircon",
    "//src/sys/test_adapters:lib",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:serde",
    "//third_party/rust_crates:serde_derive",
    "//third_party/rust_crates:serde_json",
    "//third_party/rust_crates:thiserror",
    "//third_party/rust_crates:uuid",
  ]

  non_rust_deps = [ "//zircon/public/lib/fdio" ]

  # TODO(46728): Fix the leaks and remove this.
  non_rust_deps += [ "//build/config/sanitizers:suppress-lsan.DO-NOT-USE-THIS" ]
}

test_package("gtest_adapter_tests") {
  deps = [
    ":bin",
    ":bin_test",
    "test_data",
  ]

  binaries = [
    {
      name = "gtest_adapter"
    },
    {
      name = "sample_tests"
    },
    {
      name = "no_tests"
    },
  ]

  tests = [
    {
      name = "gtest_adapter_bin_test"
      environments = basic_envs
    },
  ]
}

group("gtest") {
  testonly = true
  public_deps = [ ":bin" ]
}

group("tests") {
  testonly = true
  public_deps = [
    ":gtest_adapter_tests",
    "tests",
  ]
}