src/ledger/bin/p2p_sync/impl/BUILD.gn

# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/fuzzing/fuzzer.gni")
import("//third_party/flatbuffers/flatbuffer.gni")

visibility = [ "//src/ledger/*" ]

source_set("impl") {
  sources = [
    "commit_batch.cc",
    "commit_batch.h",
    "device_mesh.h",
    "encoding.cc",
    "encoding.h",
    "flatbuffer_message_factory.cc",
    "flatbuffer_message_factory.h",
    "ledger_communicator_impl.cc",
    "ledger_communicator_impl.h",
    "message_holder.h",
    "page_communicator_impl.cc",
    "page_communicator_impl.h",
    "user_communicator_impl.cc",
    "user_communicator_impl.h",
  ]

  public_deps = [
    "//src/ledger/bin/environment",
    "//src/ledger/bin/p2p_provider/impl",
    "//src/ledger/bin/p2p_sync/public",
    "//src/ledger/bin/storage/public",
    "//src/ledger/lib/callback",
    "//src/ledger/lib/convert",
    "//third_party/abseil-cpp",
  ]

  deps = [
    ":message",
    "//src/ledger/lib/logging",
  ]
}

flatbuffer("message") {
  sources = [ "message.fbs" ]
}

source_set("unittests") {
  testonly = true

  sources = [
    "commit_batch_unittest.cc",
    "encoding_unittest.cc",
    "page_communicator_impl_unittest.cc",
    "user_communicator_impl_unittest.cc",
  ]

  deps = [
    ":impl",
    ":message",
    "//sdk/lib/fidl/cpp",
    "//src/ledger/bin/p2p_provider/fake",
    "//src/ledger/bin/storage/fake:lib",
    "//src/ledger/bin/storage/testing",
    "//src/ledger/bin/testing:lib",
    "//src/ledger/lib/callback",
    "//src/ledger/lib/logging",
    "//src/ledger/lib/vmo",
    "//third_party/abseil-cpp",

    # gtest matchers are in gmock.
    "//third_party/googletest:gmock",
    "//third_party/googletest:gtest",
  ]

  configs += [ "//src/ledger:ledger_config" ]
}

fuzzer("p2p_sync_fuzzer") {
  sources = [ "user_communicator_impl_fuzztest.cc" ]
  deps = [
    ":impl",
    "//src/ledger/bin/environment:test_loop_notification",
    "//src/ledger/bin/p2p_provider/public",
    "//src/ledger/bin/storage/testing",
    "//src/ledger/lib/logging",
    "//zircon/public/lib/async-testing",
  ]
}