src/graphics/lib/magma/tests/helper/BUILD.gn

# Copyright 2016 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//src/graphics/lib/magma/gnbuild/magma.gni")

source_set("platform_device_helper") {
  public_configs = [ "$magma_build_root:magma_tests_include_config" ]

  public_deps = [
    "$magma_build_root/src/magma_util:macros",
    "$magma_build_root/src/magma_util/platform:device",
  ]

  sources = [
    "platform_device_helper.cc",
    "platform_device_helper.h",
  ]
}

source_set("command_buffer_helper") {
  public_configs = [ "$magma_build_root:magma_tests_include_config" ]

  public_deps = [ "$magma_build_root/src/magma_util/platform:device" ]

  sources = [ "command_buffer_helper.h" ]

  deps = [ "$magma_build_root/src/sys_driver" ]

  # TODO(46937): UBSan has found an instance of undefined behavior in this target.
  # Disable UBSan for this target temporarily until it is migrated into CI/CQ.
  # Add to public_configs since the UB is found in a public header.
  public_configs += [ "//build/config:temporarily_disable_ubsan_do_not_use" ]
}

source_set("test_device_helper") {
  testonly = true
  public_configs = [ "//src/graphics/lib/magma:magma_tests_include_config" ]

  public_deps = [
    "//src/graphics/lib/magma/include:magma_abi",
    "//third_party/googletest:gtest",
    "//zircon/public/lib/fdio",
    "//zircon/public/lib/zx",
    "//zircon/system/fidl/fuchsia-device:fuchsia-device_llcpp",
  ]

  sources = [ "test_device_helper.h" ]
}

source_set("logger_init_helper") {
  testonly = true
  sources = [ "logger_init_helper.cc" ]
  deps = [
    "$magma_build_root/src/magma_util/platform:logger_impl",
    "$zircon_build_root/public/lib/fdio",
    "$zircon_build_root/public/lib/zx",
  ]
}

source_set("inflight_list") {
  testonly = true

  public_configs = [ "//src/graphics/lib/magma:magma_tests_include_config" ]

  sources = [ "inflight_list.h" ]

  public_deps = [
    "$magma_build_root/include:magma_abi",
    "$magma_build_root/src/magma_util:macros",
    "$magma_build_root/src/magma_util:status",
  ]
}