| ;------------------------------------------------------------------------------ | |
| ; | |
| ; Copyright (c) 2006, Intel Corporation. All rights reserved.<BR> | |
| ; This program and the accompanying materials | |
| ; are licensed and made available under the terms and conditions of the BSD License | |
| ; which accompanies this distribution. The full text of the license may be found at | |
| ; http://opensource.org/licenses/bsd-license.php. | |
| ; | |
| ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS, | |
| ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED. | |
| ; | |
| ; Module Name: | |
| ; | |
| ; CopyMem.Asm | |
| ; | |
| ; Abstract: | |
| ; | |
| ; CopyMem function | |
| ; | |
| ; Notes: | |
| ; | |
| ;------------------------------------------------------------------------------ | |
| DEFAULT REL | |
| SECTION .text | |
| ;------------------------------------------------------------------------------ | |
| ; VOID * | |
| ; EFIAPI | |
| ; InternalMemCopyMem ( | |
| ; IN VOID *Destination, | |
| ; IN VOID *Source, | |
| ; IN UINTN Count | |
| ; ) | |
| ;------------------------------------------------------------------------------ | |
| global ASM_PFX(InternalMemCopyMem) | |
| ASM_PFX(InternalMemCopyMem): | |
| push rsi | |
| push rdi | |
| mov rsi, rdx ; rsi <- Source | |
| mov rdi, rcx ; rdi <- Destination | |
| lea r9, [rsi + r8 - 1] ; r9 <- End of Source | |
| cmp rsi, rdi | |
| mov rax, rdi ; rax <- Destination as return value | |
| jae .0 | |
| cmp r9, rdi | |
| jae @CopyBackward ; Copy backward if overlapped | |
| .0: | |
| mov rcx, r8 | |
| and r8, 7 | |
| shr rcx, 3 | |
| rep movsq ; Copy as many Qwords as possible | |
| jmp @CopyBytes | |
| @CopyBackward: | |
| mov rsi, r9 ; rsi <- End of Source | |
| lea rdi, [rdi + r8 - 1] ; esi <- End of Destination | |
| std ; set direction flag | |
| @CopyBytes: | |
| mov rcx, r8 | |
| rep movsb ; Copy bytes backward | |
| cld | |
| pop rdi | |
| pop rsi | |
| ret | |