src/diagnostics/detect/integration/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

# This directory was based on fuchsia-mirror/src/sys/component_manager/tests/utc-time/

import("//build/component/config.gni")
import("//build/components.gni")
import("//build/fidl/fidl.gni")
import("//build/rust/rustc_binary.gni")

group("integration") {
  testonly = true
  deps = [ ":tests" ]
}

group("tests") {
  testonly = true
  deps = [ ":detect-integration-test" ]
}

rustc_test("integration_test_bin") {
  edition = "2021"
  source_root = "integration_test.rs"
  name = "detect_integration_test"
  deps = [
    "//sdk/fidl/fuchsia.diagnostics:fuchsia.diagnostics_rust",
    "//sdk/fidl/fuchsia.feedback:fuchsia.feedback_rust",
    "//sdk/fidl/fuchsia.io:fuchsia.io_rust",
    "//src/lib/diagnostics/testing/fake-archive-accessor",
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/lib/fuchsia-component-test",
    "//src/lib/zircon/rust:fuchsia-zircon",
    "//src/sys/lib/component-events",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:async-trait",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:tracing",
  ]

  sources = [
    "fake_crash_reporter.rs",
    "fake_crash_reporting_product_register.rs",
    "integration_test.rs",
    "test_filing_enable.rs",
    "test_snapshot_sanitizing.rs",
    "test_snapshot_throttle.rs",
    "test_trigger_truth.rs",
  ]
}

fuchsia_component("integration-test-component") {
  testonly = true
  manifest = "meta/integration-test.cml"
  deps = [ ":integration_test_bin" ]
}

# Run with `fx test detect-integration-test`.
fuchsia_test_package("detect-integration-test") {
  test_components = [ ":integration-test-component" ]
  deps = [
    "//src/diagnostics/detect:triage-detect-component",
    "//src/diagnostics/detect:triage-detect-test-config",
  ]
}